salesforce 零基础学习（六十七）SingleEmailMessage 那点事

　　public void sendEmailWithoutEmailTemplateToOrgUsers() {
        Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
        email.setSenderDisplayName('the sender name you want to show');
        email.setPlainTextBody('test email text');
        email.setSubject('test email subject');
        email.setTargetObjectId('00528000002MLtt');//使用此种方式给org内部User/Contact/Lead发邮件，email limit的count不加1
        email.setSaveAsActivity(false);//如果设置targetObjectId，则必须设置setSaveAsActivity为false
        Messaging.sendEmail(new List<Messaging.SingleEmailMessage>{email});
    }

    public void sendEmailWithoutEmailTemplateToExtraUser() {
        Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
        email.setSenderDisplayName('the sender name you want to show');
        email.setHtmlBody('<span color="red">测试html body内容</span>');
        email.setSubject('test email subject use html');
        //addresses which you wanna send to
        List<String> toAddresses = new List<String>();
        toAddresses.add('xx@qq.com');
        email.setToAddresses(toAddresses);
        Messaging.sendEmail(new List<Messaging.SingleEmailMessage>{email});
    }

    public void sendEmailWithTextTemplateUseMergeField() {
        EmailTemplate temp =  [
            SELECT Id, Name, Subject, HtmlValue, Body, BrandTemplateId
            FROM EmailTemplate
            WHERE DeveloperName = 'Test_Text_With_Merge_Field'
            LIMIT 1
        ];
        Contact con = [SELECT Id FROM Contact where name = 'york zhang'];
        Goods__c goods = [select Id,GoodsName__c from Goods__c where GoodsName__c != null limit 1];
        Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();

        //set display name,the value will show sender name
        email.setSenderDisplayName('the sender name you want to show');

        //if use template,targetObjectId will be required
        email.setTargetObjectId(con.Id);

        //for default,the email will send to targetObject's email,
        //if you don't want to send target object (user/contact/lead),just setTreatTargetObjectAsRecipient false 
        email.setTreatTargetObjectAsRecipient(false);

        //if target object id is user or contact,set saveAsActivity false
        email.setSaveAsActivity(false);

        //set merge object id only if target object instanceof contact
        email.setWhatId(goods.Id);

        //set template id
        email.setTemplateId(temp.Id);
        
        List<String> toAddresses = new List<String>{'xx@qq.com'};
        email.setToAddresses(toAddresses);
        Messaging.sendEmail(new List<Messaging.SingleEmailMessage>{email});
    }

    public void sendEmailWithTextTemplateUseFormat() {
        EmailTemplate temp =  [
            SELECT Id, Name, Subject, HtmlValue, Body, BrandTemplateId
            FROM EmailTemplate
            WHERE DeveloperName = 'Test_Text_With_Format'
            LIMIT 1
        ];
        String subjectFormat = String.format(temp.Subject, new List<String>{'test subject title'});
        String bodyFormat = String.format(temp.Body,new List<String>{'test param1','test param2'});
        Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
        Contact con = [SELECT Id FROM Contact where name = 'york zhang'];
        email.setTargetObjectId(con.Id);
        email.setSaveAsActivity(false);
        email.setSubject(subjectFormat);
        email.setPlainTextBody(bodyFormat);
        email.setTemplateId(temp.Id);
        Messaging.sendEmail(new List<Messaging.SingleEmailMessage>{email});
    }

    public void sendEmailWithHtmlTemplateUseFormat() {
        EmailTemplate temp =  [
            SELECT Id, Name, Subject, HtmlValue, Body, BrandTemplateId
            FROM EmailTemplate
            WHERE DeveloperName = 'Test_Text_With_Html'
            LIMIT 1
        ];

        String subjectFormat = String.format(temp.Subject, new List<String>{'test subject title'});
        String bodyFormat = String.format(temp.HtmlValue,new List<String>{'test param1','test param2'});
        Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
        Contact con = [SELECT Id FROM Contact where name = 'york zhang'];
        email.setTargetObjectId(con.Id);
        email.setSaveAsActivity(false);
        email.setSubject(subjectFormat);
        email.setHtmlBody(bodyFormat);
        email.setTemplateId(temp.Id);
        Messaging.sendEmail(new List<Messaging.SingleEmailMessage>{email});

    }

<messaging:emailTemplate subject="Test Subject Use Visualforce Component" language="{!recipient.Languages__c}" recipientType="Contact" relatedToType="Goods__c">
    <messaging:htmlEmailBody>
        <style type="text/css">
            p {
                border: 3px;
                background: #cccccc;
            }
        </style>
        <div>
            this is a visualforce component email template
        </div>
        <div>
            <p>{!$ObjectType.Goods__c.Fields.GoodsName__c.Label} : {!relatedTo.GoodsName__c}</p>
            <p>{!$ObjectType.Contact.Fields.Name.Label} : {!recipient.Name}</p>
        </div>
    </messaging:htmlEmailBody>
    <messaging:attachment filename="ExportGoods.csv">
        <apex:repeat value="{!relatedTo}" var="goods">
            {!goods.GoodsName__c}
            {!goods.GoodsBrand__c}
        </apex:repeat>
    </messaging:attachment>
</messaging:emailTemplate>

    public void sendEmailWithVisualforceComponent() {
        EmailTemplate temp =  [
            SELECT Id, Name, Subject, HtmlValue, Body, BrandTemplateId
            FROM EmailTemplate
            WHERE DeveloperName = 'Test_Email_Template_With_Component'
            LIMIT 1
        ];
        //String subjectFormat = String.format(temp.Subject, new List<String>{'test subject title'});
        Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
        Contact con = [SELECT Id FROM Contact where name = 'york zhang'];
        Goods__c goods = [select id from Goods__c limit 1];
        email.setTargetObjectId(con.Id);
        email.setSaveAsActivity(false);
        email.setWhatId(goods.Id);
        email.setTemplateId(temp.Id);
        Messaging.sendEmail(new List<Messaging.SingleEmailMessage>{email});
    }