AS3中的单件(Singleton)模式

单件(singleton)模式在c#中是最容易实现的模式,其主要用意就在于限制使用者用new来创建多个实例。但在as3中,构造函数必须是public的(语法本身要求的),而且也不能在构造函数中抛出异常(编译可通过,但是逻辑行不通),因为这样相当于把创建实例的路子完全切断了,一个实例也得不到!

错误代码:

package{
	public class singleton{
		
		static private var _instance:singleton;
		
		public function singleton():void{
			throw Error("单件模式不能用new创建实例!");
		}
		
		public static function getInstance():singleton{
			if (_instance==null){
				_instance = new singleton();//因为上面的构造函数抛出了异常,所以这里运行时会报错
			}
			return _instance;
		} 
			
	}
}

怎样即能创建实例,又阻止使用者调用构造函数呢?这里要用到as3的一个特性:默认情况下,一个as文件,只能放一个类,而且必须用package声明,但有一种特殊情况:一个as文件中定义二个类,一个用package声明,一个不用!没有package的类,默认访问范围为“仅同在一个文件的类可访问”

package
{

	public class SingletonFactory
	{
		private static var _instance:Singleton2=null;

		public function SingletonFactory():void
		{
			trace Error("error!");
		}

		public static function getInstance():Singleton2
		{
			if (_instance == null)
			{
				_instance=new Singleton2();
			}
			return _instance;
		}
	}
}

class Singleton2
{
	import flash.utils.getTimer;

	private var _createTime:uint;

	public function Singleton2()
	{
		_createTime=getTimer();
	}

	public function toString():String
	{
		return "本实例的创建时间:" + _createTime.toString();
	}

	public function helloWorld(name:String):String
	{
		return "hello " + name + " !";
	}
}

测试:

package
{
	import flash.display.Sprite;
	import flash.utils.getTimer;
	
	public class main extends Sprite
	{
		public function main()
		{			
			var a:* = SingletonFactory.getInstance();
			trace(getTimer());
			
			var s1:* = SingletonFactory.getInstance();
			trace(s1.toString());
			
			//空循环,刻意占用cpu,消耗占时间而已
			for(var i:uint=0;i<999999;i++)
			{
				//trace();
			}
			
			trace(getTimer());
			var s2:* = SingletonFactory.getInstance();
			trace(s2.toString());
			
			trace(s1==s2);
			
			trace(s1.helloWorld("jimmy"));
			
			
		}
	}
}

但这里有一个不爽的地方,SingleTon2类离开了文件SingletonFactory.as就无法访问了,所以我们在使用时,只能用var s1:* 来声明,虽然可以使用,但是在fd,fb等编程环境中却无法获得代码自动感知!

可以借助接口改进一下:

package
{
	public interface ISingleton
	{
		function toString():String;
		
		function helloWorld(name:String):String;
	}
}

然后让SingleTon2实现该接口

package
{

	public class SingletonFactory
	{
		private static var _instance:Singleton2=null;

		public function SingletonFactory():void
		{
			trace Error("error!");
		}

		public static function getInstance():Singleton2
		{
			if (_instance == null)
			{
				_instance=new Singleton2();
			}
			return _instance;
		}
	}
}

class Singleton2 implements ISingleton //这里改为实现接口
{
	import flash.utils.getTimer;

	private var _createTime:uint;

	public function Singleton2()
	{
		_createTime=getTimer();
	}

	public function toString():String
	{
		return "本实例的创建时间:" + _createTime.toString();
	}

	public function helloWorld(name:String):String
	{
		return "hello " + name + " !";
	}
}

重新测试:

package
{
	import flash.display.Sprite;

	public class main extends Sprite
	{
		public function main()
		{
			var s:ISingleton=SingletonFactory.getInstance();
			trace(s.helloWorld("jimmy.yang"));
		}
	}
}

当然明白了上面的原理后,其实可以更一步简化,既然不声明package的类,只能限制在同一个文件内部的其它类可以访问,何不把它做为构造函数的参数?(这样不就限制了从外部调用构造函数么)

package
{
	public class Singleton2
	{
		private static var _instance:Singleton2;
		
		public function Singleton2(n:_nothing)
		{
				
		}
		
		public static function getInstance():Singleton2{
			if (_instance==null){
				_instance = new Singleton2(new _nothing());				
			}	
			return _instance;
		}
	}
}

class  _nothing{}

这样就清爽多了,当然Singleton模式在AS3中的实现方法不止一种,下面这种也许更容易理解:

package{
	
	public class Singleton{
		
		private static var _instance:Singleton = null;
		
		public function Singleton(){
			if(_instance == null){
				_instance = this;
			}else{
				throw Error("已经存在该类的实例!");
			}
		}
		
		public static function getInstance():Singleton{
			if(_instance != null){
				return _instance;
			}
			return new Singleton();
		}		
		
	}
}

本文参与腾讯云自媒体分享计划,欢迎正在阅读的你也加入,一起分享。

发表于

我来说两句

0 条评论
登录 后参与评论

相关文章

来自专栏IT可乐

Java设计模式之(一)------单例模式

1、什么是单例模式?   采取一定的办法保证在整个软件系统中,单例模式确保对于某个类只能存在一个实例。有如下三个特点:   ①、单例类只能有一个实例   ②、单...

22670
来自专栏技术碎碎念

sql server T-SQL 基础

SQL语言按照用途可以分为如下3类: ①DDL(Data Definition Language)  数据定义语言:    定义修改和删除数据库、表、索引和视图...

29860
来自专栏JavaEdge

为什么java中用枚举实现单例模式会更好代码简洁

代码简洁 这是迄今为止最大的优点,如果你曾经在Java5之前写过单例模式代码,那么你会知道即使是使用双检锁你有时候也会返回不止一个实例对象。虽然这种问题通过...

61740
来自专栏程序猿DD

漫画:什么是单例模式?(整合版)

————— 第二天 ————— 单例模式第一版: public class Singleton { private Singleton() {} ...

240100
来自专栏yukong的小专栏

【ssm个人博客项目实战07】博客的后台实现什么是循环引用和重复引用关闭循环引用/重复引用

在前面我们已经完成了博客类别的添加修改删除分页查询操作了,现在我们就来完成了博客的添加修改

26530
来自专栏java 成神之路

多线程并发下的单例模式

48570
来自专栏Java帮帮-微信公众号-技术文章全总结

【数据库】MySQL进阶七、limit用法& varchar类型排序

【数据库】MySQL进阶七、 limit用法与varchar排序 limit用法 limit是mysql的语法 select * from table limi...

35360
来自专栏杨建荣的学习笔记

MySQL中需要注意的字段长度问题

在MySQL的表结构设计中,突然想起来几个地方碰到的问题比较多,大体来说一个就是字符集,一个就是数据类型。 而字符集和数据类型结合起来,就有一个蛮有意思的细节,...

41860
来自专栏禁心尽力

数据库设计之数据库,数据表和字段等的命名总结

数据库命名规则: 根据项目的实际意思来命名。 数据表命名规则: 1.数据表的命名大部分都是以名词的复数形式并且都为小写; 2.尽量使用前缀"table_"; 3...

26050
来自专栏应兆康的专栏

Python Web - Flask笔记5

MySQL Workbench是一款专为MySQL设计的ER/数据库建模工具。它是著名的数据库设计工具DBDesigner4的继任者。你可以用MySQL Wor...

19410

扫码关注云+社区

领取腾讯云代金券