Flash小品之颜色解析

/*! 
    \file ARGBColor.as
    \brief this is simple color class for color converting
*/

package  
{
	
	public class ARGBColor
	{
		// color value
        private var a:uint;
		private var r:uint;
		private var g:uint;
		private var b:uint;
		
		// default constructor
		public function ARGBColor(value:uint=0)
		{
			SetColor(value);
		}
		
		//! set color value
		public function SetColor(value:uint):void
		{
		    splitColor(value);
		}
		
		//! set color value
		public function SetColorARGB(a:uint, r:uint, g:uint, b:uint):void
		{
			SetA(a);
			SetR(r);
			SetG(g);
			SetB(b);
		}
		
		//! get color value
		public function GetColor():uint
		{
			return mergeColor();
		}
		
		//! set alpha value
		public function SetA(a_:uint):void
		{
		    a = a_;
			a = clamp(a, 0, 0xFF);
		}
		
		//! get alpha value
		public function GetA():uint
		{
			return a;
		}
		
		//! set red value
		public function SetR(r_:uint):void
		{
			r = r_;
			r = clamp(r, 0, 0xFF);
		}
		
		//! get red value
		public function GetR():uint
		{
			return r;
		}
		
		//! set green value
		public function SetG(g_:uint):void
		{
			g = g_;
			g = clamp(g, 0, 0xFF);
		}
		
		//! get green value
		public function GetG():uint
		{
			return g;
		}
		
		//! set blue value
		public function SetB(b_:uint):void
		{
			b = b_;
			b = clamp(b, 0, 0xFF);
		}
		
		//! get blue value
		public function GetB():uint
		{
			return b;
		}
		
		// split color
		private function splitColor(value:uint):void
		{
		    a = ((value >> 24) & 0xFF); // seems in Flash '>>' is signed shfiting
			r = ((value >> 16) & 0xFF);
			g = ((value >> 8) & 0xFF);
			b = (value & 0xFF);
		}
		
		// merge color
		private function mergeColor():uint
		{
			return (a << 24) | (r << 16) | (g << 8) | b;
		}
		
		// clamp helper function
		private function clamp(val:Number, min:Number, max:Number):Number
		{
            return Math.max(min, Math.min(max, val));
        }
		
	}
	
}