在ABAP里取得一个数据库表记录数的两种方法

Jerry Wang

发布于 2019-05-30 18:44:22

4640

发布于 2019-05-30 18:44:22

文章被收录于专栏：Jerry的SAP技术分享 Jerry的SAP技术分享Jerry的SAP技术分享

方法1：使用函数EM_GET_NUMBER_OF_ENTRIES

这个函数使用起来很简单，只需要将想查询的数据库表名称维护进输入参数IT_TABLES:

上图说明这个函数支持批量操作，我查询的两张表名为TADIR和PROGDIR.

执行函数，得到表的条目数：

方法2:使用ADBC

方法1的实现其实没有什么神奇之处，就是用Open SQL SELECT COUNT(*)来取得一张表的数据个数。

如果我们使用的ABAP Netweaver底层数据库用的是SAP HANA，那么有一张元数据表M_TABLES，存放了所有表的元数据。

看个例子：

下面一条SQL语句，可以轻松获得表COMM_PRODUCT和TADIR的条目数：

SELECT * FROM M_TABLES WHERE TABLE_NAME IN (‘COMM_PRODUCT’, ‘TADIR’)

我写了个简单的ABAP工具，把对表M_TABLES的操作封装了起来：

class CL_CRM_HOME_TABLE_SIZE_TOOL definition

public

final

create public .

public section.

TYPES: BEGIN OF ty_size,

table_name TYPE char256,

record_count TYPE int4,

table_size TYPE int4,

END OF ty_size.

TYPES: tt_size TYPE TABLE OF ty_size with key table_name.

class-methods GET_SIZE

importing

!IT_INPUT type STRING_TABLE

returning

value(RT_RESULT) type tt_size .

protected section.

private section.

ENDCLASS.

CLASS CL_CRM_HOME_TABLE_SIZE_TOOL IMPLEMENTATION.

METHOD get_size.

DATA(lv_in) = REDUCE string( INIT x TYPE string FOR <data> IN it_input NEXT x = SWITCH #( x

WHEN space THEN |'{ <data> }'| ELSE x && ',' && |'{ <data> }'| ) ).

TRY.

DATA(lo_sql_con) = cl_sql_connection=>get_connection( ).

DATA(lo_stmt) = lo_sql_con->create_statement( ).

DATA: lv_stmt TYPE string.

lv_stmt = |select table_name, record_count, table_size from m_tables where table_name in ({ lv_in })|.

DATA(lo_res) = lo_stmt->execute_query( lv_stmt ).

GET REFERENCE OF rt_result INTO DATA(lr_data).

lo_res->set_param_table( lr_data ).

lo_res->next_package( ).

lo_res->close( ).

CATCH cx_sql_exception INTO DATA(cx_root).

WRITE:/ 'Error:', cx_root->get_text( ).

RETURN.

ENDTRY.

ENDMETHOD.

ENDCLASS.

上述class的消费方式：

REPORT zsize.

DATA: lt_input TYPE String_table.

lt_input = VALUE #( ( CONV string( 'TADIR' ) )

( CONV string( 'TFDIR' ) )

).

DATA(lt_size) = cl_crm_home_table_size_tool=>get_size( lt_input ).

cl_demo_output=>display_data( lt_size ).

执行上述report，显示的结果如下：