SAS-那些统计过程步的统计量的输出...

Ods Output summary=temp1 ;
proc means data = sashelp.cars range sum var mean nmiss median Skewness Kurtosis  q1  q3 ;
  var cylinders;                
  class make;
  output out=temp2 n = cnt sum = total mean = avg;
run;
ods output close;
/*n 有效数据记录数   q3 第三分位数; nmiss 缺失数据记录   cv变异系数
mean 均值   var方差 std 标准差   css离均差平方和
median 中位数    clm 95%可信区间 qrange 四分位数间距   max 最大值
ql  第一分位数    min 最小值 Skewness峰度  Kurtosis 偏度 */

/*************************************
proc univariate输出的统计量：
Moments  矩
BasicMeasures 位置和可变性的基本测度
BasicIntervals 基本置信区间
TestsForLocation 位置检验
TestsForNormality 正态检验
Quantiles  分位数
ExtremeObs  极值观测
Frequencies   频数
**************************************/

Ods Output Moments=Moments 
BasicMeasures=BasicMeasures
BasicIntervals=BasicIntervals
TestsForLocation=TestsForLocation
TestsForNormality=TestsForNormality
Quantiles=Quantiles
ExtremeObs=ExtremeObs
Frequencies=Frequencies
;
proc univariate data=sashelp.class cibasic cipctldf alpha=0.5 normal PLOT FREQ ;              /*配对样本的符号检验*/
var age;
output out=sd pctlpre=P_  pctlpts=50,95 to 100 by 2.5,2 ;
run;
ods output close;
*PLOT 画图 FREQ频数  normal 此选项可用来要求 UNIVARIATE 过程检定分析的变量是否呈现正态分布并且输出其检验结果。
UNIVARIATE 统计值及对应含义
N 非缺失值个数    NMISS缺失值个数     NOBS观察体总数     MEAN平均数    SUM变量值的总和 STD标准差
VAR变异系数（标准误）   SKEWNESS偏度      KURTOSIS峰度   SUMWT所有观察体在WEIGHT变量上的总和
MAX最大值    MIN最小值     RANGE 最大值减去最小值所得的差   Q3 第三个四分位数
MEDIAN中位数   Q1第一个四分位数 QRANGE  Q3减去Q1之差
P1第1 的百分位数    P5第5 的百分位数     P10第10 的百分位数   P90第90 的百分位数
P95第95 的百分位数    P99第99 的百分位数
MODE 众数如果有不只一个众数取最小值的那一个
SIGNRANK 等级符号检定法 (The Signed Rank Statistic Lehmann 1975)
NORMAL 常态分配的检定 (Test Statistic for Normality)若观察体个数少于 51 则采用Shapiro-Wilk 的 W Statistic 的方法检定否则采用用 Kolomogorov;

/*************************************
为研究某职业人群颈椎病发病的性别差异，今随机抽查了该职业人群男性120人和女性110人，发现男性中有36人患有颈椎病，女性中有22人患有颈椎病。试作统计推断
设 原假设H0：俩组人群无差异  备择假设H1:俩组人群有显著性差异.

卡方输出统计量：采用output形式输出统计量到指定数据集
CrossTabFreqs输出行列表的频数和百分率、
CMH输出CMH检验的统计量和p值、
FishersExact输出Fisher确切概率检验的p值、
Chisq输出卡方检验的统计量和p值
**************************************/
Proc datasets library=work kill nolist;
quit;
data a;
input g1 g2 val;
cards;
1 1 36
1 2 84
2 1 22
2 2 88
;
run;
ods listing  ;
ods html close ;
Ods Output CrossTabFreqs=CrossTabFreqs1 CMH=CMH Chisq=Chisq   FishersExact=FishersExact CommonRelRisks=CommonRelRisks;
proc freq data=a ; 
table  g1*g2/Expected CMH Chisq Fisher;
weight Val ;
run;
ods output close;

ods html;
ods select Plots;
proc univariate data=sashelp.class  plot  ;              
var weight;
run;