VBA专题07：使用VBA读写Windows注册表

Windows注册表用于存储与计算机相关的各种设置，VBA中的GetSetting函数和SaveSetting函数能够读写Windows注册表，这样，我们不仅能够获取应用程序和硬件的信息，也可以将应用程序中的信息存储在注册表中以供使用。

SaveSetting

SaveSetting语句在Windows注册表中创建或保存一个应用程序项。其语法为：

SaveSetting appname, section,key, setting

其中：

1.参数appname，必需，字符串类型，指定应用程序的名称。

2.参数section，必需，字符串类型，指定区段名称，在该区段保存注册表项设置。

3.参数key，必需，字符串类型，指定要保存的注册表项名称。

4.参数setting，必需，字符串类型或数值类型，指定key的设置值。

说明：

1.该函数将值写入注册表中的HKEY_CURRENT_USER\Software\VBand VBA Program Settings键的子键。

2.如果在注册表中没有找到appname或者section子键，则会自动创建它们。

3.VB把setting作为字符串值写入注册表中。如果setting不是字符串，则会试图把它改成字符串以便写入注册表。

4.如果不能保存设置，则会导致运行时错误。

5.SaveSetting不允许改变注册表项的缺省值。

GetSetting

GetSetting函数从注册表中的应用程序项返回注册表项的设置值。其语法为：

GetSetting(appname, section,key[,default])

其中：

1.参数appname，必需，字符串类型，指定应用程序的名称，该应用程序有注册表项设置。

2.参数section，必需，字符串类型，指定区段名称，在该区段有注册表项设置。

3.参数key，必需，字符串类型，返回注册表项设置的名称。

4.参数default，可选，如果注册表项设置中没有设置值，则返回该缺省值。如果省略该参数，则其值是一个零长字符串（””）。

说明：

1.该函数从注册表中的HKEY_CURRENT_USER\Software\VBand VBA Program Settings键的子键中检索值。

2.该函数返回字符串值。因此，在使用从注册表返回的数值型值之前，应该使用合适的转换函数将返回值转换为数值数据类型。

3.GetSetting不能检索注册表项的缺省值。

GetAllSetting

GetAllSetting语句返回应用程序的注册表项及其相应的值，是一个Variant型的二维字符串数组。其语法为：

GetAllSetting(appname, section)

其中：

1.参数appname，必需，字符串类型，指定应用程序的名称。

2.参数section，必需，字符串类型，指定区段名称，在该区段有注册表项设置。

说明：

1.该函数从注册表中的HKEY_CURRENT_USER\Software\VBand VBA Program Settings键的子键中检索值。

2.该函数返回的数组中的第一维元素为项名，第二维元素为各个项的值。

3.该函数返回的二维数组的下标从0开始。因此，第一个注册表项名可以通过引用元素（0,0）获取。

4.该函数只能返回属于section指定的最终注册表主键的注册表项名和数据。如果主键含有一个或多个子键，则不能用这个函数读取它们的数据。

DeleteSetting

DeleteSetting语句删除应用程序子键或数值项。其语法为：

DeleteSetting appname[, section[, key]]

其中：

1.参数appname，必需，字符串类型，指定应用程序的名称。

2.参数section，可选，字符串类型，指定区段名称，可以是一个键或用反斜杠分开的注册表路径。

3.参数key，可选，字符串类型，要删除数值的注册表设置项名称。

说明：

1.该函数从注册表中的HKEY_CURRENT_USER\Software\VBand VBA Program Settings键的子键中删除值。

2.如果指定了参数key，那么只有名为key的数值项及其相关联的值被删除；如果忽略参数key，那么名为section的子键将被删除；如果忽略参数section，那么名为appname的应用程序子键将被删除。

3.DeleteSetting不能删除注册表项的缺省值。

4.除非确定好了，否则不要随便删除注册表项设置，以免误删除导致严重的后果。

示例

1.下面的代码将应用程序设置项写入注册表：

Sub TestControlReg()
    SaveSetting "完美Excel", _
        "excelperfect\VBADev\MyPro",_
        "TestKey", "100"
    MsgBox "可以查看注册表了!"
End Sub

此时，打开注册表编辑器，导航到HKEY_CURRENT_USER\Software\VBand VBA Program Settings键下，会发现新增子键，如下图1所示。

图1

2.下面的代码从注册表中获取指定注册表项值：

Sub TestControlReg1()
    Dim val As Long
    val = GetSetting("完美Excel", _
        "excelperfect\VBADev\MyPro",_
        "TestKey")
       
    MsgBox val
End Sub

运行代码后的结果如下图2所示。

图2

3.下面的代码删除指定键的注册表设置项名称：

Sub testCotrolReg2()
    DeleteSetting "完美Excel", _
      "excelperfect\VBADev\MyPro", _
      "TestKey"
    MsgBox "看看注册表!"
End Sub

4.下面是一段综合示例代码，演示了创建注册表项、更新注册表项、打印注册表项、打印所有注册表项、删除注册表项等操作。

Sub testReg()
    Dim vKeys As Variant
   
   '创建注册表项
    SaveSetting "MyAppTest","General", "MyApp_Name", "完美Excel"
    SaveSetting "MyAppTest","General", "MyApp_Ver", "1.0"
    SaveSetting "MyAppTest","General", "MyApp_Date", "2019/10/17"
   '打印注册表项值
    PrintRegSettings
   
   '更新注册表项
    SaveSetting "MyAppTest","General", "MyApp_Ver", "1.1"
    SaveSetting "MyAppTest","General", "MyApp_Date", "2019/10/20"
   '打印注册表项值
    PrintRegSettings
   
   '获取并打印所有注册表项值
    vKeys =GetAllSettings("MyAppTest", "General")
    PrintAllSettings vKeys
   
   '删除所有注册表项
    DeleteSetting "MyAppTest","General", "MyApp_Name"
    DeleteSetting "MyAppTest","General", "MyApp_Ver"
    DeleteSetting "MyAppTest","General", "MyApp_Date"
    PrintRegSettings
End Sub
 
Sub PrintRegSettings()
    Dim str As String
   
    On Error Resume Next
    str = "应用程序名称:" & _
        GetSetting("MyAppTest","General", "MyApp_Name") & _
        vbCrLf & "应用程序版本:" &_
        GetSetting("MyAppTest","General", "MyApp_Ver") & _
        vbCrLf & "更新日期:" &_
        GetSetting("MyAppTest","General", "MyApp_Date")
   
    MsgBox str
End Sub
 
Sub PrintAllSettings(vSettings As Variant)
    Dim i As Integer
    If IsArray(vSettings) Then
        For i = 0 To UBound(vSettings)
            Debug.Print vSettings(i, 0) &": " & _
                vSettings(i, 1)
        Next i
    End If
End Sub

有兴趣的朋友可以自已动手实践一下上述测试程序，以此来熟悉VBA中的这几个操控注册表的函数。