.sas7bdat文件与.xpt文件批量转换

/*SAS文件路径*/
libname sdata "/home/users/zenga/code/sas/";

/*XPT文件路径*/
%let dir=/home/users/zenga/code/xpt/;

filename xpts pipe "ls &dir.*.xpt";

data _null_;
    infile xpts truncover;
    input;
    XPTFILE=prxchange('s/(.+)\/(.+)(\.xpt)/\2/',-1, _INFILE_);
    call execute('libname xptin xport "&dir.'||strip(XPTFILE)||'.xpt";'
                 ||'proc copy in=xptin out=sdata mt=all; run;');
run;

filename xpts clear;
 

/*XPT文件路径*/
%let dir=/home/users/zenga/code/xpt/;

proc sql;
    create table vtable as
        select * 
        from dictionary.tables
        where LIBNAME='SDATA'
        ;
quit;

data _null_;
    set vtable end=eof;
    MEMNAME=lowcase(MEMNAME);
    call execute('libname temp xport "&dir.'||cats(MEMNAME)||'.xpt";'
                 ||'data '||cats(MEMNAME)||'(sortedby=_null_ label="'||cats(MEMLABEL)||'"); set sdata.'||cats(MEMNAME)||'; run;'
                 ||'proc copy in=work out=temp mt=data; select '||cats(MEMNAME)||'; run;');
    if eof then call execute('libname temp clear;');
run;