VBA Object对象的函数参数传递
VBA的函数参数传递方式是Byval和Byref，数值类型、Stirng等那些值类型的是要非常注意用哪种方式的。对于Object对象引用类型的一直都说2种方式完全没有区别。
Object对象的Byval和Byref参数真的没有区别吗？
对于操作的这个Object对象来说，可以认为是没有区别，但是传递过程和其他数据类型的参数传递是一样的，遵守的规则并没有改变。
- ByVal 参数传递的时候，会在内存中另外复制一份，函数操作这个副本和传递之前的那个变量已经没有了任何关系；
- Byref 会把参数的内存地址传递给函数，函数接收到这个是通过内存地址来读取或者改写的，操作的就是原来的变量。
对于Object对象，其实我们传递的只是他的指针，也就是VarPtr得到的那个数字，是指向Object所在内存的地址。
可以理解为参数其实就是一个LongPtr类型，所以你是复制一份这个LongPtr类型的数字传递，还是把这个LongPtr类型所在的内存地址传递给函数，对于Object这个对象来说，是没有区别的。它最终都要通过这个数字所代表的内存地址找到Object对象。
Sub TestObject()
Dim rng As Range
Set rng = Range("A1")
Dim VarPtr中保存的数据 As Long
CopyMemory VarPtr(VarPtr中保存的数据), VarPtr(rng), 4
Printf "VarPtr(rng) = x0%x, ObjPtr(rng) = 0x%x, VarPtr中保存的数据 = 0x%x", VarPtr(rng), ObjPtr(rng), VarPtr中保存的数据
TestObjectByVal rng
TestObjectByValByRef rng
End Sub
Function TestObjectByVal(ByVal rng As Range)
Dim VarPtr中保存的数据 As Long
CopyMemory VarPtr(VarPtr中保存的数据), VarPtr(rng), 4
Printf "ByVal: VarPtr(rng) = x0%x, ObjPtr(rng) = 0x%x, VarPtr中保存的数据 = 0x%x", VarPtr(rng), ObjPtr(rng), VarPtr中保存的数据
End Function
Function TestObjectByValByRef(ByRef rng As Range)
Dim VarPtr中保存的数据 As Long
CopyMemory VarPtr(VarPtr中保存的数据), VarPtr(rng), 4
Printf "ByRef: VarPtr(rng) = x0%x, ObjPtr(rng) = 0x%x, VarPtr中保存的数据 = 0x%x", VarPtr(rng), ObjPtr(rng), VarPtr中保存的数据
End Function
输出：
VarPtr(rng) = x022edd0, ObjPtr(rng) = 0xfaaddd0, VarPtr中保存的数据 = 0xfaaddd0
ByVal: VarPtr(rng) = x022ecc0, ObjPtr(rng) = 0xfaaddd0, VarPtr中保存的数据 = 0xfaaddd0
ByRef: VarPtr(rng) = x022edd0, ObjPtr(rng) = 0xfaaddd0, VarPtr中保存的数据 = 0xfaaddd0从打印输出可以看出，Byval传递需要复制参数，其实只是把保存对象地址的那个内存地址，也就是VarPtr得到的那个地址复制改变了，而这个地址中保存的数据仍然是ObjPtr的那个地址。
本文参与 腾讯云自媒体同步曝光计划，分享自微信公众号。
原始发表：2020-03-26，如有侵权请联系 cloudcommunity@tencent.com 删除
评论
登录后参与评论
推荐阅读
腾讯云开发者
