VBA解析复合文档04——解析目录信息

Private Type CFDir
    EntryName(63) As Byte
    EntryNameLen As Integer
    ObjectType As Byte                    '1仓storage 2流 5根
    ColorFlag As Byte                     '0红色 1黑色
    LeftSiblingID As Long                 '-1表示叶子
    RightSiblingID As Long
    ChildID As Long
    CLSID(16 - 1) As Byte
    StateBits As Long
    CreationTime As Date
    ModifiedTime As Date
    StartingSectorID As Long               '目录入口所表示的第1个扇区编码
    StreamSize As Long                     '目录入口流尺寸，可判断是否是短扇区
    not_used As Long    '我是32位office，读不了64位整数！
    
    '这个不是结构体的字段
    StrDirName As String
    '在文件中的偏移位置
    lOffset As Long
End Type

'解析目录
Private Function parseDir() As String
    Dim l_sub_dir As Long
    Dim l_SID As Long
    Dim k As Long
    Dim i As Long
    Dim lOffset As Long
    
    l_SID = cf.Header.FirstDirSID

    k = 0
    Do
        lOffset = getOffsetBySID(l_SID)
        '设置读取的位置
        cf.r.SeekFile lOffset, OriginF
        
        ReDim Preserve cf.ArrDir(k + 4 - 1) As CFDir
        For i = 0 To 4 - 1
            cf.r.Read cf.ArrDir(k + i).EntryName
            cf.ArrDir(k + i).EntryNameLen = cf.r.ReadInteger()
            '名称长度为0就可以退出了
            If cf.ArrDir(k + i).EntryNameLen = 0 Then Exit Do
            
            cf.ArrDir(k + i).ObjectType = cf.r.ReadByte()                  '1仓storage 2流 5根
            cf.ArrDir(k + i).ColorFlag = cf.r.ReadByte()                  '0红色 1黑色
            cf.ArrDir(k + i).LeftSiblingID = cf.r.ReadLong()             '-1表示叶子
            cf.ArrDir(k + i).RightSiblingID = cf.r.ReadLong()
            cf.ArrDir(k + i).ChildID = cf.r.ReadLong()
            cf.r.Read cf.ArrDir(k + i).CLSID
            cf.ArrDir(k + i).StateBits = cf.r.ReadLong()
            cf.ArrDir(k + i).CreationTime = cf.r.ReadDate()
            cf.ArrDir(k + i).ModifiedTime = cf.r.ReadDate()
            cf.ArrDir(k + i).StartingSectorID = cf.r.ReadLong()             '目录入口所表示的第1个扇区编码
            cf.ArrDir(k + i).StreamSize = cf.r.ReadLong()           '目录入口流尺寸，可判断是否是短扇区
            cf.ArrDir(k + i).not_used = cf.r.ReadLong()
            
            
            If cf.ArrDir(k + i).EntryName(0) <= 5 Then
                cf.ArrDir(k + i).StrDirName = VBA.CStr(cf.ArrDir(k + i).EntryName(0))
                cf.ArrDir(k + i).EntryName(0) = VBA.Asc("]")
                cf.ArrDir(k + i).StrDirName = "[" & cf.ArrDir(k + i).StrDirName & VBA.Left$(cf.ArrDir(k + i).EntryName, cf.ArrDir(k + i).EntryNameLen \ 2 - 1)
                
            Else
                cf.ArrDir(k + i).StrDirName = VBA.Left$(cf.ArrDir(k + i).EntryName, cf.ArrDir(k + i).EntryNameLen \ 2 - 1) '-1包含结尾的0
            End If
            
            cf.ArrDir(k + i).lOffset = lOffset
            lOffset = lOffset + DIR_SIZE
            
        Next
    
        k = k + 4
        l_SID = cf.FAT(l_SID)
    Loop Until l_SID = End_Of_Chain_SID
    
    '去掉最后的一个空白
    ReDim Preserve cf.ArrDir(k + i - 1) As CFDir
    
    recordDir
    
    GetDirsName
End Function

'记录dir的完整名称到hash
Private Function recordDir() As String
    '记录目录名称的Hash
    Set cf.h = NewCHash(UBound(cf.ArrDir) + 1)
    
    RrecordDir cf.ArrDir(0), "", 0
End Function
Private Function RrecordDir(d As CFDir, preDir As String, dirIndex As Long)
    cf.h.Add preDir & d.StrDirName, dirIndex
    d.StrDirName = preDir & d.StrDirName
    
    If d.LeftSiblingID = -1 And d.RightSiblingID = -1 And d.ChildID = -1 Then
        Exit Function
    End If
    
    If d.LeftSiblingID <> -1 Then RrecordDir cf.ArrDir(d.LeftSiblingID), preDir, d.LeftSiblingID
    If d.RightSiblingID <> -1 Then RrecordDir cf.ArrDir(d.RightSiblingID), preDir, d.RightSiblingID
    If d.ChildID <> -1 Then RrecordDir cf.ArrDir(d.ChildID), d.StrDirName & Application.PathSeparator, d.ChildID
End Function

'读取短扇区配置表（Allocator for mini stream  user-defined data）
'是一个SID数组
Private Function parseMiniFAT() As String
    Dim l_SID As Long
    Dim i As Long, j As Long

    If cf.Header.MiniFATSectorsCount = 0 Then Exit Function
    
    cf.lShortSectorSize = 2 ^ cf.Header.MiniSectorShift
    cf.ssNumPerSector = cf.lSectorSize / cf.lShortSectorSize
    
'    根目录的 stream_size 表示短流存放流的大小，每64个为一个short sector
    ReDim cf.MiniFAT(cf.ArrDir(0).StreamSize / cf.lShortSectorSize - 1) As Long

    l_SID = cf.Header.FirstMiniFATSID    '短流起始SID
    
    For i = 0 To UBound(cf.MiniFAT) Step cf.longNumPerSector
        '设置读取的位置
        cf.r.SeekFile getOffsetBySID(l_SID), OriginF
        
        For j = 0 To cf.longNumPerSector - 1
            cf.MiniFAT(i + j) = cf.r.ReadLong()
            
            If i + j = UBound(cf.MiniFAT) Then Exit For
        Next
        
        l_SID = cf.FAT(l_SID)
    Next

End Function