VBA与数据库——写个类操作ADO_DB信息

'保存当前打开的DBPath到DBOperate.sqlite
Sub rbSaveDBPath(control As IRibbonControl)
    If VBA.Len(MPublic.scbInput) Then
        If VBA.MsgBox("DB描述：" & MPublic.scbInput & vbNewLine & "DBPath：" & DB_Info.Path & vbNewLine & "确认按此添加？", vbYesNo) = vbYes Then
            If MPublic.dbinfo.ExecuteNonQuery("insert into dbpath(描述, path, SType) values('" + MPublic.scbInput + "','" + DB_Info.Path + "', '" + VBA.CStr(MPublic.dbinfo.GetDBType) + "')") Then
                MsgBox MPublic.dbinfo.GetErr
            End If
        End If
    Else
        MsgBox "请在Input中输入DB的描述。"
    End If
End Sub

'保存Input中的sql到DBOperate.sqlite
Sub rbSaveSQL(control As IRibbonControl)
    If VBA.Len(MPublic.scbInput) = 0 Then
        MsgBox "请在Input中输入sql语句。"
        Exit Sub
    End If
    
    Dim s描述 As String
    
    s描述 = Application.InputBox("SQL：" & VBA.Left$(MPublic.scbInput, 255 - 4 - 2 * 2 - 30) & vbNewLine & vbNewLine & "输入此sql的描述，保存到DBOperate.sqlite。", Type:=2)
    
    If s描述 = "False" Then Exit Sub
    
    Dim strsql As String
    '如果里面有“'”，需要替换一下
    strsql = MPublic.scbInput
    If VBA.InStr(strsql, "'") Then strsql = VBA.Replace(strsql, "'", "''")
    
    If MPublic.dbinfo.ExecuteNonQuery("insert into commonSQL(描述, dbpathID, strsql) values('" + s描述 + "',(select ID from dbpath where path='" + DB_Info.Path + "'), '" + strsql + "')") Then
        MsgBox MPublic.dbinfo.GetErr
    End If
End Sub

Sub rbDelDBPath(control As IRibbonControl)
    If DB_Info.db Is Nothing Then
        MsgBox "请选择数据库。"
        Exit Sub
    End If
    
    If VBA.MsgBox("DBPath：" & DB_Info.Path & vbNewLine & "确定从BOperate.sqlite中删除？", vbYesNo) = vbYes Then
        If MPublic.dbinfo.ExecuteNonQuery("delete from dbpath where path='" + DB_Info.Path + "'") Then
            MsgBox MPublic.dbinfo.GetErr
        End If
    End If
End Sub

Sub rbDelSQL(control As IRibbonControl)
    If DB_Info.db Is Nothing Then
        MsgBox "请选择数据库。"
        Exit Sub
    End If
    
    If VBA.Len(MPublic.scbInput) = 0 Then
        MsgBox "请在Input中选择sql语句。"
        Exit Sub
    End If
    
    If VBA.MsgBox("DBPath：" & DB_Info.Path & vbNewLine & "SQL：" & MPublic.scbInput & vbNewLine & "确定从BOperate.sqlite中删除sql语句？", vbYesNo) = vbYes Then
        ' TODO 没效果
        If MPublic.dbinfo.ExecuteNonQuery("delete from commonSQL where strsql||' -- '||描述='" + MPublic.scbInput + "' and dbpathID=(select ID from dbpath where path='" + DB_Info.Path + "')") Then
            MsgBox MPublic.dbinfo.GetErr
        End If
    End If
End Sub