Power BI 折线图自定义特殊标注

特殊标注折线图 = 
VAR XMinDate =
    MINX ( ALLSELECTED ( '表'[Date] ), '表'[Date] )
VAR XMaxDate =
    MAXX ( ALLSELECTED ( '表'[Date] ), '表'[Date] )
VAR MaxWidth =
    INT ( XMaxDate - XMinDate ) //图表的宽度
VAR MaxHeight = MaxWidth / 2 //图表的高度
VAR Space_X = MaxWidth * 0.1
VAR Space_Y = MaxHeight * 0.1
VAR Label_Size = MaxWidth / 30
VAR Mark_r = MaxWidth / 60
VAR Line_stroke = MaxWidth / 100
VAR YMinValue =
    MINX ( ALLSELECTED ( '表'[Date] ), [指标] )
VAR YMaxValue =
    MAXX ( ALLSELECTED ( '表'[Date] ), [指标] )
VAR SVG_Table =
    ADDCOLUMNS (
'表',
"X", INT ( [Date] - XMinDate ),
"Y",
            MaxHeight
                * DIVIDE ( [指标] - YMinValue, YMaxValue - YMinValue ),
"MarkColor",
IF ( [指标] = YMinValue, "Tomato", IF ( [指标] = YMaxValue, "DarkCyan", BLANK () ) )
    ) //内置标记最高值最低值，实际可替换为任意想标记的值
VAR Lines =
    CONCATENATEX ( SVG_Table, [X] & "," & MaxHeight - [Y], " ", [Date] ) //把线段连接到一起
VAR Marks =
    CONCATENATEX (
        FILTER ( SVG_Table, [MarkColor] <> BLANK () ),
"<circle cx='" & [X] & "' cy='" & MaxHeight - [Y] & "' r='" & Mark_r & "' fill='" & [MarkColor] & "'/>"
    )
VAR Labels =
    CONCATENATEX (
        FILTER ( SVG_Table, [MarkColor] <> BLANK () ),
"<text x='" & [X] + Mark_r & "' y='" & MaxHeight - [Y] + 3 * Mark_r & "' text-anchor='middle' font-size='" & Label_Size & "' fill='" & [MarkColor] & "'>"
            & FORMAT ( [Date], "YYYY/MM/DD" ) & "[" & [指标] & "]</text>"
    ) //把数据标签连接到一起
VAR SVG = "data:image/svg+xml;utf8," & "<svg xmlns='http://www.w3.org/2000/svg' x='0' y='0' width='" & MaxWidth & "' height='" & MaxHeight & "'  viewBox='" & - Space_X & " " & - Space_Y & " " & MaxWidth + Space_X * 2 & " " & MaxHeight + Space_Y * 2 & "'>" & "<!--微信公众号、知乎:wujunmin-->" & "<polyline fill='none' stroke='LightGrey' stroke-width='" & Line_stroke & "' points='" & Lines & "'/>" & Marks & Labels & "</svg>"
RETURN
    SVG