【源代码】VB.NET 基于EF6+CodeFirst的SQLite数据库案例，支持加密，免配置文件

https://gitee.com/BuLuoPiaoYu/sqlite-helper

xcopy $(ProjectDir)Libs\x86\* $(TargetDir)x86\* /e /i /y
xcopy $(ProjectDir)Libs\x64\* $(TargetDir)x64\* /e /y

Imports System.Data.Entity
Imports System.Data.Entity.Core.Common
Imports System.Data.SQLite
Imports System.Data.SQLite.EF6

''' <summary>
''' 配置类
''' </summary>
Public Class SQLiteConfiguration
    Inherits DbConfiguration

    ''' <summary>
    ''' 构造函数
    ''' </summary>
    Public Sub New()
        SetProviderFactory("System.Data.SQLite", SQLiteFactory.Instance)
        SetProviderFactory("System.Data.SQLite.EF6", SQLiteProviderFactory.Instance)
        SetProviderServices("System.Data.SQLite", CType(SQLiteProviderFactory.Instance.GetService(GetType(DbProviderServices)), DbProviderServices))
        SetProviderServices("System.Data.SQLite.EF6", CType(SQLiteProviderFactory.Instance.GetService(GetType(DbProviderServices)), DbProviderServices))
    End Sub
End Class

Imports System.Data.Common
Imports System.Data.Entity
Imports System.Data.Entity.ModelConfiguration.Conventions
Imports System.Data.SQLite
Imports System.IO
Imports SQLite.CodeFirst

''' <summary>
''' 数据库上下文
''' </summary>
<DbConfigurationType(GetType(SQLiteConfiguration))> '' 引入配置类
Public Class AppDbContext
    Inherits DbContext

    ''' <summary>
    ''' 构造函数
    ''' </summary>
    ''' <param name="connectionString"></param>
    Public Sub New(Optional connectionString As String = Nothing)
        MyBase.New(CreateConnection(connectionString), True)
        '------------
        Configuration.ValidateOnSaveEnabled = False
        Configuration.LazyLoadingEnabled = False
        '------------ 输出SQL日志
        Database.Log = New Action(Of String)(Sub(sql)
                                                 Trace.WriteLine(sql)
                                             End Sub)
    End Sub

    ''' <summary>
    ''' 创建链接对象
    ''' </summary>
    ''' <returns></returns>
    Private Shared Function CreateConnection(connectionString As String) As DbConnection
        If connectionString = Nothing Then
            Dim dbPath As String = Path.Combine(AppDomain.CurrentDomain.BaseDirectory, "DataBase.db3") '' 配置数据库地址
            Dim password As String = "bgmh123456" '' 配置数据库密码
            connectionString = String.Format("Data Source={0};password={1};Version=3;", dbPath, password)
        End If
        Return New SQLiteConnection(connectionString)
    End Function

    ''' <summary>
    ''' 在模型创建时进行模型配置
    ''' </summary>
    ''' <param name="modelBuilder"></param>
    Protected Overrides Sub OnModelCreating(modelBuilder As DbModelBuilder)
        ' CodeFirst创建数据库和数据表 
        ' 当模型发生变化时，适合开发环境
        Dim sqliteConnectionInitializer = New SqliteDropCreateDatabaseWhenModelChanges(Of AppDbContext)(modelBuilder)
        ' 当数据库不存在时，适合正式环境
        ' Dim sqliteConnectionInitializer = New SqliteCreateDatabaseIfNotExists(Of AppDbContext)(modelBuilder)
        Database.SetInitializer(sqliteConnectionInitializer)
        ' 移除复数表名约定
        modelBuilder.Conventions.Remove(Of PluralizingTableNameConvention)()
        ' 对模型进行配置
        ModelSQLiteConfiguration(modelBuilder)
    End Sub

    ''' <summary>
    ''' 模型配置
    ''' </summary>
    ''' <param name="modelBuilder"></param>
    Private Sub ModelSQLiteConfiguration(modelBuilder As DbModelBuilder)
        ' 配置User表的CreateTime默认值
        ' modelBuilder.Entity(Of TestTable)() _
        '     .Property(Function(u) u.DateString) _
        '     .HasDatabaseGeneratedOption(System.ComponentModel.DataAnnotations.Schema.DatabaseGeneratedOption.Computed)
    End Sub

End Class

Imports System.ComponentModel.DataAnnotations
Imports System.ComponentModel.DataAnnotations.Schema
Imports SQLite.CodeFirst

''' <summary>
''' 用户数据表
''' </summary>
Public Class TestUser

    ''' <summary>
    ''' 主键ID自增
    ''' </summary>
    ''' <returns></returns>
    <Key> ''主键
    <DatabaseGenerated(DatabaseGeneratedOption.Identity)> '' 自增ID
    Public Property Id As Integer

    ''' <summary>
    ''' 用户名
    ''' </summary>
    ''' <returns></returns>
    <Unique> ''唯一值
    Public Property Name As String

    ''' <summary>
    ''' 用户密码
    ''' </summary>
    ''' <returns></returns>
    Public Property Password As String

End Class

 ''' <summary>
 ''' 用户表数据集
 ''' </summary>
 Public Property TestUsers As DbSet(Of TestUser)