Delphi数组初始化
我目前有这个，它很糟糕：
type TpointArray = array [0..3] of Tpoint;
class function rotationTable.offsets(pType, rotState, dir: integer): TpointArray;
begin
Result[0] := point(1, 1);
Result[1] := point(1, 2);
Result[2] := point(1, 1);
Result[3] := point(1, 1);
end;相反，我想做这样的事情：
class function rotationTable.offsets(pType, rotState, dir: integer): TpointArray;
begin
Result := [Point(1,1), Point(1,2), Point(1,1), Point(1,1)];
end;然而，在编译时，它抱怨1，2，3，4语法只能用于整数。
有没有一种方法可以像我想要的那样实例化/初始化一个Tpoint数组？
回答 3
Stack Overflow用户
发布于 2010-02-20 12:44:27
记录数组可以在常量表达式中初始化：
const
Points : TPointArray = ((X: 1; Y: 1), (X:1; Y:2), (X:1; Y:1), (X:1; Y:1));
class function rotationTable.offsets(pType, rotState, dir: integer): TpointArray;
begin
Result := Points;
end;在XE7中，可以像这样填充动态记录数组：
function GetPointArray: TArray<TPoint>;
begin
Result := [Point(1,1),Point(1,2),Point(1,1),Point(1,1)];
end;Stack Overflow用户
发布于 2010-02-20 23:25:59
Plainth's answer演示了动态数组的类似构造函数的语法。您可以直接在TPoint数组上使用它来生成一个简单得多的助手函数：
type
TPointDynArray = array of TPoint;
T4PointArray = array[0..3] of TPoint;
function PointDynArrayTo4PointArray(const input: TPointDynArray): T4PointArray;
var
i: Integer;
begin
Assert(Length(input) = Length(Result));
for i := 0 to High(input) do
Result[i] := input[i];
end;
class function rotationTable.offsets(pType, rotState, dir: integer): T4PointArray;
begin
// New dynamic-array-constructor syntax here
Result := PointDynArrayTo4PointArray(TPointDynArray.Create(
Point(1,1), Point(1,2), Point(1,1), Point(1,1)));
end;但这太夸张了。Delphi还允许您内联定义开放数组，并且不需要编写额外的构造函数调用。结果使用您最初提出的语法，但将数组包装在函数调用中。它可以在所有的Delphi版本中工作，而上面的"Create“语法是相当新的。
function PointOpenArrayTo4PointArray(const input: array of TPoint): T4PointArray;
var
i: Integer;
begin
Assert(Length(input) = Length(Result));
for i := 0 to High(input) do
Result[i] := input[i];
end;
class function rotationTable.offsets(pType, rotState, dir: integer): T4PointArray;
begin
Result := PointOpenArrayTo4PointArray(
[Point(1,1), Point(1,2), Point(1,1), Point(1,1)]);
end;您可能想要考虑使用Gerry's answer仅仅是为了给您的点数组起有意义的名称，这在调试和这些点定义中的八个幻数之一是错误的时候可能会有所帮助。
最后，关于Delphi所说的“1，2，3，4语法只适用于整数”的含义。该语法定义的是集合，而不是数组。你不能有一组记录值，但你可以有一组整数。一个副作用是，一组整数的语法与开放整数数组的语法相同。我认为Delphi使用上下文来找出您所指的是哪一个，但有时它可能会猜错。
Stack Overflow用户
发布于 2010-02-20 15:46:30
您不能这样做，因为您不能在代码体中表达一个点，就像在const部分中表达它一样。
然而，你可以做一些技巧来让你的生活变得更容易，特别是如果你有合理的点数。
您可以像这样实现一个简单的过程(代码未经过测试)：
procedure BlendDimensions(aXArray, aYArray: TIntegerDynArray; var aResult: TPointArray);
var
nCount: integer;
i: integer;
begin
nCount:=High(aXArray);
if nCount <> High(aYArray) then
Exception.Create('The two dimension arrays must have the same number of elements!');
SetLength(aResult, nCount);
for i:=0 to nCount do
begin
aResult[i].X:=aXArray[i]; //simple copy
aResult[i].y:=aYArray[i];
end;
end;RTL TIntegerDynArray是...where的动态整数数组。(事实上，它适用于任何动态数组)。此外，上面示例中的TPointArray也是动态的。
所以，为了完成你的工作，你可以这样做：
procedure Foo;
var
myXCoords, myYCoords: TIntegerDynArray; //temp arrays
myPoints: TPointArray; //this is the real thing
begin
myXCoords:=TIntegerDynArray.Create( 1, 2, 3, 4, 5, 6, 7, 8, 9,10);
myYCoords:=TIntegerDynArray.Create(21,32,34,44,55,66,65,77,88,92); //...for example
BlendDimensions(myXCoords, myYCoords, myPoints); //build the real thing
//use it...
end;注意事项：
- 你可以清楚地看到哪些是你的要点
- ，你可以通过这种方式
- 你也可以在其他事情上使用
BlendDimensions，不仅仅是这个 - 你可以很容易地将
BlendDimensions扩展为3个(或更多) dimensions - ...but，请注意，因为涉及到副本。:-)在今天的PC中，到目前为止，弱点将是您的手。:-)你会累得打字更快，直到复印时间被注意到为止。
HTH
https://stackoverflow.com/questions/2300912
复制相似问题
腾讯云开发者
