组合深层节点
组合深层节点
提问于 2012-09-02 00:40:11
对于如何最好地继续下面的XML示例，我有点困惑：
<Story>
<Content para="div"><local>This is some (normal) text to start with.</local></Content>
<Content para="div"><local>Connect something (</local></Content>
<Content para="div"><local><refnr value="58236"/></local></Content>
<Content para="div"><local>) to something else (</local></Content>
<Content para="div"><local><refnr value="58237"/></local></Content>
<Content para="div"><local>), and make sure it's connected to this (</local></Content>
<Content para="div"><local><refnr value="58239"/></local></Content>
<Content para="div"><local>).</local></Content>
<Content para="div"><local>If that's ok do the same with this (</local></Content>
<Content para="div"><local><refnr value="58238"/></local></Content>
<Content para="div"><local>) also.</local></Content>
<Content para="div"><local>This is some normal text.</local></Content>
<Content para="div"><local>This also.</local></Content>
</Story>我希望得到的输出如下所示：
<Story>
<Content para="div"><local>This is some (normal) text to start with.</local></Content>
<Content para="div"><local>Connect something (<refnr value="58236"/>) to something else (<refnr value="58237"/>), and make sure it's connected to this (<refnr value="58239"/>).</local></Content>
<Content para="div"><local>If that's ok do the same with this (<refnr value="58238"/>) also.</local></Content>
<Content para="div"><local>This is some normal text.</local></Content>
<Content para="div"><local>This also.</local></Content>
</Story>或者，“编码”它:任何以左方括号结尾的内容para=div节点都需要与下面的内容para=div节点合并，直到包含最后一个闭括号的节点和句子的结尾(由闭合点标识)。我可以做一些事情，但它变得过于复杂和缓慢，没有所有想要的结果。对使用xslt2有什么建议吗？
Stack Overflow用户
发布于 2012-09-02 01:21:04
我认为你需要嵌套两种方法：
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="2.0">
<xsl:output indent="yes"/>
<xsl:template match="Story">
<xsl:copy>
<xsl:for-each-group select="Content" group-adjacent="contains(., '(') or contains(., ')') or boolean(self::Content[local[refnr]])">
<xsl:choose>
<xsl:when test="current-grouping-key()">
<xsl:for-each-group select="current-group()" group-ending-with="Content[local[ends-with(., '.')]]">
<Content para="div">
<local>
<xsl:copy-of select="current-group()/local/node()"/>
</local>
</Content>
</xsl:for-each-group>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="current-group()"/>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>有了这个样式表和您的示例输入，我就得到了您发布的结果。但是我不确定我使用的条件对于真实的输入是不是太简单了，例如，报告是否可以包含refnr元素的“正常”文本。
使用matches进行编辑，如
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="2.0">
<xsl:output indent="yes"/>
<xsl:template match="Story">
<xsl:copy>
<xsl:for-each-group select="Content"
group-adjacent="not(matches(., '\(.*\)'))
or boolean(self::Content[local[refnr]])">
<xsl:choose>
<xsl:when test="current-grouping-key()">
<xsl:for-each-group select="current-group()" group-ending-with="Content[local[ends-with(., '.')]]">
<Content para="div">
<local>
<xsl:copy-of select="current-group()/local/node()"/>
</local>
</Content>
</xsl:for-each-group>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="current-group()"/>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>我认为，编辑后的输入样本会根据需要进行转换。当然，一旦你有了<Content para="div"><local>Connect (foo) something (</local></Content>，这种方法也太简单了。
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/12229537
复制相关文章
相似问题
腾讯云开发者
