问为什么CMD在FreeCommander中双击启动批处理文件时找不到wsl命令？

EN

应该首先阅读以下Microsoft文档页：

• WOW64实现细节
• 文件系统重定向器
• 受WOW64影响的注册表项

64位Windows上有两个系统目录，其处理器具有AMD64体系结构：

1. 默认情况下，64位应用程序使用64位应用程序的%SystemRoot%\System32 .
2. 默认情况下，32位应用程序使用32位应用程序的%SystemRoot%\SysWOW64 .

默认情况下，系统环境变量PATH包含作为第一个文件夹路径的%SystemRoot%\System32。如果32位应用程序启动cmd.exe来处理批处理文件，则由于文件系统重定向器而启动了32位%SystemRoot%\SysWOW64\cmd.exe。

cmd.exe是通过使用本地环境变量PATHEXT和PATH搜索批处理文件中指定的文件，文件名没有文件扩展名或文件扩展名，并且没有路径，如"X不被识别为内部或外部命令、可操作程序或批处理文件“的原因是什么？在详细说明中所解释的那样。

wsl.exe属于一组可执行文件，在AMD64 Windows上仅以64位版本存在于%SystemRoot%\System32中。由于文件系统重定向，在%SystemRoot%\SysWOW64中没有32位版本由32位cmd.exe在本地 PATH中使用扩展形式的%SystemRoot%\System32搜索。由于这个原因，问题中发布的批处理文件不适用于32位cmd.exe在x64上的处理。

解决方案是将WOW64与批处理文件中的附加代码一起考虑在内：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
if exist %SystemRoot%\System32\wsl.exe set "FileNameWSL=%SystemRoot%\System32\wsl.exe" & goto RunWSLCommands
if exist %SystemRoot%\Sysnative\wsl.exe set "FileNameWSL=%SystemRoot%\Sysnative\wsl.exe" & goto RunWSLCommands
echo ERROR: Could not find wsl.exe. Script execution aborted.
setlocal EnableDelayedExpansion & for /F "tokens=1,2" %%G in ("!CMDCMDLINE!") do endlocal & if /I "%%~nG" == "cmd" if /I "%%~H" == "/c" pause
exit /B
:RunWSLCommands
for /F "tokens=*" %%g in ('%FileNameWSL% sh -c "hostname -I"') do set "ip=%%g"
%SystemRoot%\System32\netsh.exe interface portproxy add v4tov4 listenport=2375 connectport=2375 connectaddress=%ip%
%FileNameWSL% sh -c "sudo dockerd -H tcp://%ip%"
endlocal

要了解所使用的命令及其工作方式，请打开一个命令提示符窗口，在那里执行以下命令，并非常仔细地读取为每个命令显示的所有帮助页。

• echo /?
• endlocal /?
• exit /?
• for /?
• goto /?
• if /?
• netsh /?
• netsh interface /?
• netsh interface portproxy /?
• netsh interface portproxy add /?
• netsh interface portproxy add v4tov4 /?
• pause /?
• set /?
• setlocal /?