Excel实战技巧61： 处理剪切、复制和粘贴操作，使它们不会破坏已设置的单元格格式

Dim mbCut As Boolean
Dim mrngSource As Range
 
'初始化单元格的复制-粘贴
Public Sub InitCutCopyPaste()
   Application.OnKey "^X", "DoCut"
   Application.OnKey "^x", "DoCut"
   Application.OnKey "+{DEL}", "DoCut"
   
   Application.OnKey "^C", "DoCopy"
   Application.OnKey "^c", "DoCopy"
   Application.OnKey "^{INSERT}", "DoCopy"
   
   Application.OnKey "^V", "DoPaste"
   Application.OnKey "^v", "DoPaste"
   Application.OnKey "+{INSERT}", "DoPaste"
   
   Application.OnKey "{ENTER}", "DoPaste"
    Application.OnKey "~","DoPaste"
   
    '关闭拖放操作
   Application.CellDragAndDrop = False
End Sub
 
'处理剪切单元格
Public Sub DoCut()
   If TypeOf Selection Is Range Then
       mbCut = True
       Set mrngSource = Selection
       Selection.Copy
   Else
       Set mrngSource = Nothing
       Selection.Cut
   End If
End Sub
 
'处理复制单元格
Public Sub DoCopy()
   If TypeOf Selection Is Range Then
       mbCut = False
       Set mrngSource = Selection
   Else
       Set mrngSource = Nothing
   End If
   
   Selection.Copy
End Sub
 
'处理粘贴单元格
Public Sub DoPaste()
   If Application.CutCopyMode And Not mrngSource Is Nothing Then
       Selection.PasteSpecial xlValues
       If mbCut Then
            mrngSource.ClearContents
       End If
       
       Application.CutCopyMode = False
   Else
       ActiveSheet.Paste
   End If
End Sub