Excel中，函数是非常精彩的一个功能，能够帮助完成很多数据处理功能。

有时候，我们在使用了公式之后，会希望使用复制-选择性粘贴-数值，来去除公式。

这在正常使用过程中是没有问题的，可是，一旦数据是筛选过的，问题就出来了：

这个时候，如果不会VBA的话，可能会想到的办法是：

• 插入1个辅助列1，填充序号
• 再插入辅助列2
• 给筛选出来的数据写上0
• 其他可以使用ROW()函数返回行号，然后取消筛选，辅助列2数值粘贴
• 按辅助列2排序
• 这样0就到最上面了在一起了，选中数值粘贴后，再按照辅助列1排序

步骤有点多，有些麻烦！

如果能有一个在筛选状态下也可以使用的数值粘贴功能就方便多了，让我们用VBA来实现它，效果：

首先在customUI.xml中增加代码：

 <button id="rbbtnPasteValues" label="buttonname&#13;" size="large" onAction="rbbtnPasteValues" imageMso="WordCountList" />

回调函数：

Sub rbbtnPasteValues(control As IRibbonControl)
    Call MRange.PasteValues
End Sub

函数实现：

'筛选状态下可以使用的数值粘贴
Sub PasteValues()
    Dim rng As Range, AreasRng As Range
    
    If VBA.TypeName(Selection) <> "Range" Then
        Exit Sub
    End If
  
    '只需要处理筛选出来的，并且是公式的单元格
    On Error Resume Next
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    Set rng = rng.SpecialCells(xlCellTypeFormulas)
    On Error GoTo 0
    
    If Not rng Is Nothing Then
        '处理单元格的每一个区域
        For Each AreasRng In rng.Areas
            AreasRng.Value = AreasRng.Value
        Next
    End If

    Set rng = Nothing
    Set AreasRng = Nothing
End Sub