基于ESP8266 NodeMCU + DHT22 记录室内温湿度

#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <ESP8266HTTPClient.h>
#include <DHT.h>

DHT dht(D1, DHT22);     //设置Data引脚所接IO口和传感器类型

ESP8266WiFiMulti wifiMulti;           // 建立ESP8266WiFiMulti对象

#define SERVER_IP "http://serverIp/environment/info/add" // 网络服务器地址
WiFiClient client; // 创建 WiFiClient 实例化对象
HTTPClient httpClient; //创建http对象

void setup() {
  Serial.begin(115200);

  wifiMulti.addAP("无线网名", "无线网密码");
  int i = 0;
  while (wifiMulti.run() != WL_CONNECTED) {  // 此处的wifiMulti.run()是重点。通过wifiMulti.run()，NodeMCU将会在当前
    delay(1000);                             // 环境中搜索addAP函数所存储的WiFi。如果搜到多个存储的WiFi那么NodeMCU
    Serial.print(i++); Serial.print(' ');    // 将会连接信号最强的那一个WiFi信号。
  }                                          // 一旦连接WiFI成功，wifiMulti.run()将会返回“WL_CONNECTED”。这也是此处while循环判断是否跳出循环的条件。
  Serial.println('\n');                     
  Serial.print("Connected to ");Serial.println(WiFi.SSID());        // 连接的WiFI名称     
  Serial.print("IP address:\t");Serial.println(WiFi.localIP());     // NodeMCU的IP地址
  
  httpClient.begin(client, SERVER_IP); // 配置HTTP请求地址
  
  dht.begin();  // 启动DHT22
}

void loop() {
  delay(1000);                                //延时1000毫秒
  float RH = dht.readHumidity();              //读取湿度数据
  float T = dht.readTemperature();            //读取温度数据
  Serial.print("Humidity:");                  //向串口打印湿度数据
  Serial.print(RH);   
  Serial.print("%"); 
  Serial.print("  Temperature:");             //向串口打印温度数据
  Serial.print(T);            
  Serial.println("C");
  
  String requestBody = "{\"environmentNo\":\"Home\",\"humidity\":";
  requestBody += String(RH);
  requestBody += ",\"temperature\":";
  requestBody += String(T);
  requestBody += "}";
  Serial.print("requestBody:"); Serial.println(requestBody);

  Serial.print("[HTTP] begin...\n");
  //启动连接并发送HTTP报头和报文
  httpClient.addHeader("Content-Type", "application/json");
  int httpCode = httpClient.POST(requestBody);
  Serial.print("[HTTP] POST...\n");
  if (httpCode > 0) {
    Serial.printf("[HTTP] POST... code: %d\n", httpCode);
    if (httpCode == HTTP_CODE_OK) {
      const String& payload = httpClient.getString();
      Serial.println("received payload:\n<<");
      Serial.println(payload);
      Serial.println(">>");
    }
  } else {
    Serial.printf("[HTTP] POST... failed, error: %s\n", httpClient.errorToString(httpCode).c_str());
  }
}