matinal：SAP ABAP 中下拉列表的小技巧

matinal

发布于 2023-10-14 14:43:50

2330

发布于 2023-10-14 14:43:50

文章被收录于专栏：SAP TechnicalSAP Technical

公众号：matinal

下拉列表是ABAP中常用的一个元素，其提供可一系列的可选值，让客户选择输入。但在某些场景下，在提供下拉列表的同时，也需要允许用户自由输入。

先看效果：

在下拉列表中，提供了一系列的可选值。但同时也提供了一个“Free Selection”。

用户选择“Free Selection”时，会出现一个新的输入框，允许客户直接输入。效果如下：

实现代码如下：

SELECTION-SCREEN BEGIN OF LINE.
  SELECTION-SCREEN COMMENT 1(28) gv_dest FOR FIELD p_dest.
  PARAMETERS p_dest TYPE char30 AS LISTBOX VISIBLE LENGTH 30 DEFAULT 'RFC1' USER-COMMAND rfc.
  SELECTION-SCREEN POSITION 65.
  PARAMETERS p_dest_x TYPE rfcdest MODIF ID rfc.
SELECTION-SCREEN END OF LINE.

*===================================================================
INITIALIZATION.
*===================================================================
  gv_dest = 'Destination'.

  DATA: it_val TYPE vrm_values.
  INSERT VALUE #( key = 'RFC1' text = 'Description 1' ) INTO TABLE it_val.
  INSERT VALUE #( key = 'RFC2' text = 'Description 2' ) INTO TABLE it_val.
  INSERT VALUE #( key = 'RFC3' text = 'Description 3' ) INTO TABLE it_val.
  INSERT VALUE #( key = ''     text = 'Free Selection' ) INTO TABLE it_val.

  CALL FUNCTION 'VRM_SET_VALUES' EXPORTING id = 'P_DEST' values = it_val.

*===================================================================
AT SELECTION-SCREEN OUTPUT.
*===================================================================
  PERFORM pbo.


*===================================================================
AT SELECTION-SCREEN.
*===================================================================
  PERFORM pai.

*===================================================================
START-OF-SELECTION.
*===================================================================
  IF p_dest IS INITIAL.
    p_dest = p_dest_x.
  ENDIF.

  WRITE 'Selected RFC Destination is: ' && p_dest.

FORM pbo.
  IF p_dest = p_dest_x AND p_dest_x IS NOT INITIAL.
    CLEAR p_dest.
  ENDIF.

  LOOP AT SCREEN.
    IF screen-group1 = 'RFC'.
      IF p_dest = space.
        screen-active = 1.
      ELSE.
        screen-active = 0.
      ENDIF.
      MODIFY SCREEN.
    ENDIF.
  ENDLOOP.
ENDFORM.

FORM pai.

ENDFORM.

本文参与腾讯云自媒体分享计划，分享自作者个人站点/博客。

原始发表：2023-10-11，如有侵权请联系 cloudcommunity@tencent.com 删除

abap