传统ASP对Active Directory进行身份验证
传统ASP对Active Directory进行身份验证
提问于 2014-03-10 16:46:20
我有一个经典的ASP网站(对不起！)。它的某些部分需要启用NT身份验证。
理想情况下，我希望向用户提供一个很好的登录表单(而不是浏览器提示)，然后我会根据AD进行身份验证，然后执行通常的“如果成功则登录，如果失败则显示错误”的操作
这有可能吗？我在一台本地计算机上尝试了以下操作，但不确定如何正确测试是否成功，也不确定它是否扩展到针对AD的搜索
<html>
<head>
</head>
<body>
<form action="test.asp" method="post">
Username:
<input type="text" name="strUserName"><br>
Password:
<input type="password" name="strPassword"><br>
<input type="submit" name="btnSubmit">
</form>
<%
If Request.Form("strUsername") <> "" Then
Dim strADsPath
strADsPath = "WinNT://ARIA"
strUserName = Request.Form("strUserName")
strPassword = Request.Form("strPassword")
'Set adObject = GetObject("WinNT:")
'Set userObject = adObject.OpenDSObject("WinNT://" & domainName, userName, password, ADS_SECURE_AUTHENTICATION)
if (not strADsPath= "") then
Dim oADsObject
Set oADsObject = GetObject(strADsPath)
response.write "Authenticating...<br><br>"
Dim strADsNamespace
Dim oADsNamespace
strADsNamespace = left(strADsPath, instr(strADsPath, ":"))
set oADsNamespace = GetObject(strADsNamespace)
Set oADsObject = oADsNamespace.OpenDSObject(strADsPath, strUserName,strPassword, 0)
if not (Err.number = 0) then
Response.Write "<font color='red'><font size = 5><u><b>Authentication has failed...<b></u></font></font>"
Session("Auth") = "NO"
else
Response.Write "<font color='blue'>USER AUTHENTICATED!</font><br>"
Session("Auth") = "YES"
end if
end if
End If
%>
</body>
</html>那么，一旦通过身份验证，是否可以获取其他内容，如电子邮件和群组？
我尝试使用Classic ASP (VBScript), 2008 R2, error using AD to authenticate并尝试在我的本地机器上进行身份验证，但无论我输入什么内容，它都会进行身份验证。是不是因为我使用的是本地机器，所以它就不能工作？
回答 1
Stack Overflow用户
发布于 2015-02-09 19:10:31
我知道这是一个老生常谈的问题，但如果有人仍然感兴趣：
这就是我根据AD对用户进行身份验证的方法:这是一种使用经过身份验证的LDAP查询的间接方法。如果查询失败，则不允许用户对域控制器进行身份验证。
它有一点不优雅，因为它需要一个明确的域控制器命名。域名(如果要使用sam帐户名)和用于搜索起始DN的OU。
dim domainController : domainController = "yourdc.company.com"
dim ldapPort : ldapPort = 389
dim startOu : startOu = "DC=company,DC=com"
Function CheckLogin( szUserName, szPassword)
CheckLogin = False
szUserName = trim( "" & szUserName)
dim oCon : Set oCon = Server.CreateObject("ADODB.Connection")
oCon.Provider = "ADsDSOObject"
oCon.Properties("User ID") = szUserName
oCon.Properties("Password") = szPassword
oCon.Open "ADProvider"
dim oCmd : Set oCmd = Server.CreateObject("ADODB.Command")
Set oCmd.ActiveConnection = oCon
' let's look for the mail address of a non exitsting user
dim szDummyQuery : szDummyQuery = "(&(objectCategory=person)(samaccountname=DeGaullesC))"
dim szDummyProperties : szDummyProperties = "mail"
dim cmd : cmd = "<" & "LDAP://" & domainController & ":" & ldapPort & _
"/" & startOu & ">;" & szDummyQuery & ";" & szDummyProperties & ";subtree"
oCmd.CommandText = cmd
oCmd.Properties("Page Size") = 100
on error resume next
dim rs : Set rs = oCmd.Execute
if err.Number = 0 then
CheckLogin = true
call rs.Close()
set rs = nothing
end if
on error goto 0
set oCmd = nothing
End Function
' perform test
dim res : res = CheckLogin( "youradname\youruser", "yourpassword")
if res then
Response.Write( "Login ok")
else
Response.Write( "Login failed")
end if页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/22295550
复制相关文章
相似问题
腾讯云开发者
