Excel VBA中的函数重载和UDF
我正在使用Excel VBA来编写一个UDF。我想用几个不同的版本重载我自己的UDF，这样不同的参数将调用不同的函数。
由于VBA似乎不支持这一点，有没有人能建议一个好的，不混乱的方法来实现同样的目标呢？我应该使用可选参数，还是有更好的方法？
回答 4
Stack Overflow用户
发布于 2008-09-16 08:59:23
将参数声明为Optional Variants，然后可以使用IsMissing()测试它们是否缺失，或者使用TypeName()检查它们的类型，如下面的示例所示：
Public Function Foo(Optional v As Variant) As Variant
If IsMissing(v) Then
Foo = "Missing argument"
ElseIf TypeName(v) = "String" Then
Foo = v & " plus one"
Else
Foo = v + 1
End If
End Function可以在工作表中以=FOO(number)，或=FOO("string").的形式调用=FOO()
Stack Overflow用户
发布于 2008-09-16 10:51:42
如果您可以通过参数计数来区分，那么下面这样的代码将会起作用：
Public Function Morph(ParamArray Args())
Select Case UBound(Args)
Case -1 '' nothing supplied
Morph = Morph_NoParams()
Case 0
Morph = Morph_One_Param(Args(0))
Case 1
Morph = Two_Param_Morph(Args(0), Args(1))
Case Else
Morph = CVErr(xlErrRef)
End Select
End Function
Private Function Morph_NoParams()
Morph_NoParams = "I'm parameterless"
End Function
Private Function Morph_One_Param(arg)
Morph_One_Param = "I has a parameter, it's " & arg
End Function
Private Function Two_Param_Morph(arg0, arg1)
Two_Param_Morph = "I is in 2-params and they is " & arg0 & "," & arg1
End Function如果区分函数的唯一方法是通过类型，那么您实际上将不得不做C++和其他具有覆盖函数的语言所做的事情，即通过签名调用。我建议让调用看起来像这样：
Public Function MorphBySig(ParamArray args())
Dim sig As String
Dim idx As Long
Dim MorphInstance As MorphClass
For idx = LBound(args) To UBound(args)
sig = sig & TypeName(args(idx))
Next
Set MorphInstance = New MorphClass
MorphBySig = CallByName(MorphInstance, "Morph_" & sig, VbMethod, args)
End Function并创建一个具有多个方法的类，这些方法与您期望的签名匹配。不过，您可能需要一些错误处理，并且要注意可识别的类型是有限的:例如，日期是TypeName Double。
Stack Overflow用户
发布于 2008-09-15 16:35:21
VBA是凌乱的。我不确定有没有一种简单的方法来做假重载：
在过去，我要么使用了很多可选的，要么使用了不同的函数。例如
Foo_DescriptiveName1()
Foo_DescriptiveName2()我建议使用具有合理默认值的可选参数，除非参数列表将变得愚蠢，然后创建单独的函数来调用您的案例。
https://stackoverflow.com/questions/64436
复制相似问题
腾讯云开发者
Copyright © 2013 - 2026 Tencent Cloud. All Rights Reserved. 腾讯云 版权所有
深圳市腾讯计算机系统有限公司 ICP备案/许可证号：粤B2-20090059 
粤公网安备44030502008569号
腾讯云计算（北京）有限责任公司 京ICP证150476号 | 京ICP备11018762号