Oracle Delete语句:级联delete已删除了多少行
Oracle Delete语句:级联delete已删除了多少行
提问于 2013-01-21 20:54:10
我正在执行一条语句，比如
DELETE FROM USER WHERE USER_ID=1;在SQLDeveloper中。
因为在许多表中都引用了用户(例如，用户有一个订单、设置...)我们激活了删除级联，这样我们就不必手动删除每一行。然而，在开发时，我们有兴趣知道有多少行和哪些表被级联删除“自动”删除。
有没有办法找出这一点。通过SQL语句，直接在sqldeveloper中从日志文件或任何其他想法？
回答 1
Stack Overflow用户
回答已采纳
发布于 2013-01-21 21:46:50
虽然使用sql%rowcount无法做到这一点，但如果您编写触发器代码，则可以做到这一点，但这意味着您需要在要监视的所有表上都有一个触发器。此外，触发器还会稍微减慢操作。
例如：
SQL> select * from one;
ID
----------
1
2
SQL> select * from child_of_one;
ID O_ID
---------- ----------
1 1
2 1
3 1
4 2
5 2
6 2
7 2
8 2我们想要一个包规格来保存表+计数的数组：
SQL> create or replace package foo
2 as
3 type rowcount_tab is table of pls_integer index by varchar2(30);
4 t_rowcount rowcount_tab;
5 end foo;
6 /
Package created.我们希望顶层表上的触发器将这些计数重置为零：
SQL> create or replace trigger one_biud
2 before insert or update or delete
3 on one
4 declare
5 begin
6 foo.t_rowcount.delete;
7 end;
8 /
Trigger created.这里假设您只对从顶层表中删除的数组感兴趣。如果不是这样，您可能需要在每个表上使用foo.t_rowcount.delete('TABLE_NAME')触发器。
现在，对每个感兴趣的表使用after for each row触发器来设置数组：
SQL> create or replace trigger one_aiudfer
2 after insert or update or delete
3 on one
4 for each row
5 declare
6 begin
7 if (foo.t_rowcount.exists('ONE'))
8 then
9 foo.t_rowcount('ONE') := nvl(foo.t_rowcount('ONE'), 0)+1;
10 else
11 foo.t_rowcount('ONE') := 1;
12 end if;
13 end;
14 /
Trigger created.
SQL> create or replace trigger child_of_one_aiudfer
2 after insert or update or delete
3 on child_of_one
4 for each row
5 declare
6 begin
7 if (foo.t_rowcount.exists('CHILD_OF_ONE'))
8 then
9 foo.t_rowcount('CHILD_OF_ONE') := nvl(foo.t_rowcount('CHILD_OF_ONE'), 0)+1;
10 else
11 foo.t_rowcount('CHILD_OF_ONE') := 1;
12 end if;
13 end;
14 /
Trigger created.现在，当我们删除或其他任何东西时：
SQL> delete from one where id = 1;
1 row deleted.
SQL> declare
2 v_table varchar2(30);
3 begin
4 v_table := foo.t_rowcount.first;
5 loop
6 exit when v_table is null;
7 dbms_output.put_line(v_table || ' ' || foo.t_rowcount(v_table) || ' rows');
8 v_table := foo.t_rowcount.next(v_table);
9 end loop;
10 end;
11 /
CHILD_OF_ONE 3 rows
ONE 1 rows
PL/SQL procedure successfully completed.
SQL> delete from one where id = 2;
1 row deleted.
SQL> declare
2 v_table varchar2(30);
3 begin
4 v_table := foo.t_rowcount.first;
5 loop
6 exit when v_table is null;
7 dbms_output.put_line(v_table || ' ' || foo.t_rowcount(v_table) || ' rows');
8 v_table := foo.t_rowcount.next(v_table);
9 end loop;
10 end;
11 /
CHILD_OF_ONE 5 rows
ONE 1 rows页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/14439097
复制相关文章
相似问题
腾讯云开发者
