问NetLogo:邻居和特征向量

EN

首先，我的主要建议是让NW正常工作。我很乐意为你效劳。

除此之外，下面假设您使用的是无向网络。如果这不是演员阵容，让我知道。

您所描述的方法的问题是，它会多次计算一些邻居的邻居。相反，您可以获取邻居的邻居代理集，然后对其进行计数：

to-report neighbors-of-neighbors
  report turtle-set [ link-neighbors ] of link-neighbors
end

然后，[ count neighbors-of-neighbors ] of turtle 0将给出turtle 0的邻居的邻居数量。

现在，有几点：

这将包括海龟本身，因为海龟始终是其链路邻居的链路邻居。如果您不想包含海龟本身，那么只需在其中添加一个other：[ count other neighbors-of-neighbors ] of turtle 0。

这将不包括作为海龟0的链接邻居的海龟，但不链接到海龟0的任何其他邻居。要在中添加这些内容，您可以考虑如下过程：

to-report turtles-in-link-radius [ n ]
  let result turtle-set self
  repeat n [
    set result (turtle-set result [ link-neighbors ] of result)
  ]
  report result
end

例如，可以像这样使用：[ count turtle-in-link-radius 2 ] of turtle 0来计算所有的海龟，最多从海龟0开始计算2跳。这个报告器具有与nw:turtles-in-radius相同的行为，尽管它的速度要慢得多。

现在，我首先注意到你的想法会多次计算一些乌龟。假设你对特征向量中心性之类的东西感兴趣，也许这就是你想要的。在这种情况下，您可以这样做：[ sum [ count link-neighbors ] of link-neighbors ] of turtle 0来获取它，而不必为海龟自己的东西而烦恼。也就是说，如果你使用海龟自己的，你实际上可以计算特征向量中心度本身：

turtles-own [
  ...
  next-ec ;; helper variable for iteratively computing eigenvector-centrality
  eigenvector-centrality
  ...
]

to calculate-eigenvector-centralities
  ask turtles [
    set eigenvector-centrality 1
  ]
  repeat 100 [  ;; the higher this number, the more accurate the value. NW uses 100
    ask turtles [
      set next-ec sum [ eigenvector-centrality ] of link-neighbors
    ]
    let max-ec max [ next-ec ] of turtles
    ask turtles [
      set eigenvector-centrality next-ec / max-ec ;; normalize
    ]
  ]
end

调用calculate-eigenvector-centralities计算所有海龟的特征向量中心度。然后，海龟的特征向量中心将被存储在eigenvector-centrality中。请注意，此代码不适用于断开连接的网络:每个组件都必须独立标准化，这就是NW所做的，但在NetLogo中，如果不使用NW，就没有简单的方法可以做到这一点。