问更好的方法是在for循环中执行多个delete

EN

CREATE TABLE table1 ( id NUMBER PRIMARY KEY );
CREATE TABLE table2 ( id NUMBER PRIMARY KEY, parent_id NUMBER );
CREATE TABLE table3 ( id NUMBER PRIMARY KEY, parent_id NUMBER );
CREATE TABLE table4 ( id NUMBER PRIMARY KEY, parent_id NUMBER );

INSERT INTO table1 ( id )
SELECT 1 FROM DUAL UNION ALL
SELECT 2 FROM DUAL UNION ALL
SELECT 3 FROM DUAL;

INSERT INTO table2 ( id, parent_id )
SELECT id + 0.1, id FROM table1 UNION ALL
SELECT id + 0.2, id FROM table1;

INSERT INTO table3 ( id, parent_id )
SELECT id + 0.01, id FROM table2 UNION ALL
SELECT id + 0.02, id FROM table2;

INSERT INTO table4 ( id, parent_id )
SELECT id + 0.001, id FROM table3 UNION ALL
SELECT id + 0.002, id FROM table3;

CREATE TYPE number_list IS TABLE OF NUMBER;

DECLARE
  p_to_delete  number_list;
  p_to_delete2 number_list;
BEGIN
  SELECT id
  BULK COLLECT INTO p_to_delete
  FROM   table4
  WHERE  id IN ( 3.112, 2.121 );
  
  DBMS_OUTPUT.PUT_LINE( 'Table 4: ' || p_to_delete.COUNT || ' rows to be deleted.' );

  DELETE FROM table4
  WHERE  id MEMBER OF p_to_delete
  RETURNING parent_id BULK COLLECT INTO p_to_delete2;
  
  DBMS_OUTPUT.PUT_LINE( 'Table 4: ' || SQL%ROWCOUNT || ' rows deleted.' );

  DBMS_OUTPUT.PUT_LINE( 'Table 3: ' || p_to_delete2.COUNT || ' rows to be deleted.' );

  DELETE FROM table3
  WHERE  id MEMBER OF p_to_delete2
  RETURNING parent_id BULK COLLECT INTO p_to_delete;
  
  DBMS_OUTPUT.PUT_LINE( 'Table 3: ' || SQL%ROWCOUNT || ' rows deleted.' );
  
  DBMS_OUTPUT.PUT_LINE( 'Table 2: ' || p_to_delete.COUNT || ' rows to be deleted.' );

  DELETE FROM table2
  WHERE  id MEMBER OF p_to_delete
  RETURNING parent_id BULK COLLECT INTO p_to_delete2;
  
  DBMS_OUTPUT.PUT_LINE( 'Table 2: ' || SQL%ROWCOUNT || ' rows deleted.' );

  DBMS_OUTPUT.PUT_LINE( 'Table 1: ' || p_to_delete2.COUNT || ' rows to be deleted.' );

  DELETE FROM table1
  WHERE  id MEMBER OF p_to_delete2;
  
  DBMS_OUTPUT.PUT_LINE( 'Table 1: ' || SQL%ROWCOUNT || ' rows deleted.' );
END;
/