删除已筛选的可见行，运行时错误1004:不能对重叠选择使用该命令。
删除已筛选的可见行，运行时错误1004:不能对重叠选择使用该命令。
提问于 2022-02-10 13:53:13
我需要删除可见的过滤行。
我拿到这个Run-time error 1004: Cannot use that command on overlapping selections了。
我的数据在第一行上有标题。
提前，非常感谢你的帮助。
Sub Macro2()
Dim rng As Range: Set rng = ActiveSheet.Range("A1:Q6880")
rng.AutoFilter Field:=8, Criteria1:="0"
rng.Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete
End Sub回答 2
Stack Overflow用户
回答已采纳
发布于 2022-02-10 20:41:41
在某些情况下，过滤会造成区域重叠的不连续范围。请尝试下一种方式，这样可以消除这些重叠：
Sub MacroDeleteFilteredRows()
Dim rng As Range: Set rng = ActiveSheet.Range("A1:Q6880")
rng.AutoFilter field:=8, Criteria1:="0"
Intersect(ActiveSheet.cells, rng.Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow).Delete
End Sub对过滤范围内没有任何可见单元格的情况进行错误处理是很好的，即使这种情况不太可能.
Stack Overflow用户
发布于 2022-02-10 15:20:10
删除过滤行
Option Explicit
Sub Macro2()
Dim ws As Worksheet: Set ws = ActiveSheet ' improve!
If ws.AutoFilterMode Then ws.AutoFilterMode = False
Dim rng As Range: Set rng = ws.Range("A1:Q6880")
' If your range is contiguous (no empty rows or columns):
'Dim rng As Range: Set rng = ws.Range("A1").CurrentRegion
Dim fcrg As Range: Set fcrg = rng.Columns(8) ' Filter Column Range
' Filter Column Data Range (no headers)
Dim fcdrg As Range: Set fcdrg = fcrg.Resize(fcrg.Rows.Count - 1).Offset(1)
fcrg.AutoFilter Field:=1, Criteria1:="0"
Dim vfcdrg As Range ' Visible Filter Column Data Range
On Error Resume Next
Set vfcdrg = fcdrg.SpecialCells(xlCellTypeVisible)
On Error GoTo 0
ws.AutoFilterMode = False
If vfcdrg Is Nothing Then Exit Sub ' no filtered values
vfcdrg.EntireRow.Delete
End Sub页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/71066351
复制相关文章
相似问题
腾讯云开发者
