问在一个单元格中同时有逗号和破折号的单元格中的计数数

EN

Function countNumb(strNo As String) As Long
    Dim arr, i As Long
    
    arr = Split(Replace(Replace(strNo, " ", ""), "-", ":"), ",")
    For i = 0 To UBound(arr)
        If Not InStr(arr(i), ":") > 0 Then
            arr(i) = arr(i) & ":" & arr(i)
        End If
    Next
    countNumb = Intersect(Range(Join(arr, ",")), Range("A:A")).cells.count
    Debug.Print Range(Join(arr, ",")).Address 'only to visually see the built range before intersection address...
End Function

Sub testCountNumbers()
    Dim x As String: x = "2,4,5,7-9"
    Debug.Print countNumb(x)
End Sub

Function AddNumbers(rngTarget As Range) As Long
    Dim arrValues() As String
    Dim lngValue As Long
    Dim strValue As String
    Dim lngMinimum As Long
    Dim lngMaximum As Long

    arrValues = Split(rngTarget.Text, ",")
    
    For lngValue = LBound(arrValues) To UBound(arrValues)
    
        strValue = arrValues(lngValue)
                
        If InStr(strValue, "-") > 0 Then
        
            lngMinimum = CLng(Left(strValue, InStr(strValue, "-") - 1))
            
            lngMaximum = CLng(Replace(strValue, lngMinimum & "-", vbNullString))
        
            AddNumbers = AddNumbers + ((lngMaximum - lngMinimum) + 1)
        
        Else
        
            AddNumbers = AddNumbers + 1
        
        End If
    
    Next lngValue
        
End Function