问如何用批处理文件从文件中的特定行读取特定字符？

EN

两个字节值可以从文件中读取，如下代码所示：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
set "FileName=%TEMP%\%~n0.tmp"
(
echo [0xA1 rr]
echo I2C START BIT
echo WRITE: 0xA1 ACK
echo READ: 0x61
echo READ:  ACK 0xA8
echo NACK
echo I2C STOP BIT
echo I2C^>
echo I2C^>
)>"%FileName%"

set "Byte01="
set "Byte02="
for /F "usebackq skip=3 tokens=2,3" %%I in ("%FileName%") do if not defined Byte01 (set /A "Byte01=%%I") else (set /A "Byte02=%%J" & goto Output)

:Output
if defined Byte01 (
    echo The byte values are:
    echo/
    set Byte
)
del "%FileName%"
endlocal

带有使用选项的命令跳过文件的前三行。

第四行首先使用默认的字符串分隔符、普通空格和水平选项卡拆分为子字符串。第二个子字符串是0x61，它被分配给指定的循环变量I。第四行没有第三个子字符串。

if 条件检查环境变量Byte01是否在FOR循环上显式地未定义，在这种情况下，使用命令SET来计算一个算术表达式，该表达式将分配给循环变量I的字符串值0x61解释为十六进制值，并将此值以十进制形式分配给环境变量Byte01。

然后，FOR处理第五行，使用空格/制表符作为分隔符，再次将该行拆分成子字符串，并根据ASCII表分配第二个子字符串(令牌) ACK来循环变量I，将第三个子字符串0xA8分配给next (但只有一个循环变量J )。

接下来将再次执行IF条件，但这一次Byte01已被定义为在命令块上继续进行批处理，命令SET用于计算用于定义环境变量Byte02的算术表达式，分配给循环变量J的十六进制值转换为十进制值E 131和e 232命令e 133GOTOE 234继续处理标签Output下面一行的批处理文件。这导致循环在处理文件中的更多行之前退出。

要了解所使用的命令及其工作方式，请打开一个命令提示符窗口，在那里执行以下命令，并非常仔细地读取为每个命令显示的所有帮助页。

• call /? ...解释%~n0 (参数0的名称，即批处理文件名)
• del /?
• echo /?
• endlocal /?
• for /?
• if /?
• set /?
• setlocal /?

另请参阅：

• 有关使用命令重定向运算符的微软文档
• 使用Windows批处理文件使用多条命令的单行