在MS-project中按任务名称自动添加资源
在MS-project中按任务名称自动添加资源
提问于 2019-11-03 04:22:46
我希望只为MS-project中的某些任务(子任务)自动添加资源名，例如，如果任务是CMM，我希望自动将CMM添加到资源名称中，这是我的代码。
Sub Automatically()
Dim NR As MsProject.Resource
Dim Tsk As MsProject.Task
Dim Row As Integer
For each row in Ms.Project.Task
If Tsk = "CMM" Or "EDM" Or "EL Milling" Or "CAM Wire cut" Or "Laser Welding" Or "Wire cut" Or "CNC Milling" Or "Grinding" Or "Lathe" Or "Manual Milling" Or "Polishing"
Set NR = NR.Resource.Add.Tsk
End If
If Tsk = "Inspection" Or "Report" Then
Set NR = "CMM"
End if
Next row
End Sub回答 1
Stack Overflow用户
回答已采纳
发布于 2019-11-03 05:57:16
此代码根据任务名称将资源分配给任务。考虑到任务名称通常比单个单词更具描述性，代码使用包含搜索(例如，Like)。如果资源不存在，则添加该资源。
Sub AddResourceAssignments()
Dim resName As String
Dim tsk As Task
For Each tsk In ActiveProject.Tasks
' determine the resource to add to the task
Select Case True
Case (tsk.Name Like "*Gate*"): resName = "Gate"
Case (tsk.Name Like "*CMM*"): resName = "CMM"
Case (tsk.Name Like "*EDM*"): resName = "EDM"
Case (tsk.Name Like "*EL Milling*"): resName = "EL Milling"
Case (tsk.Name Like "*CAM Wire cut*"): resName = "CAM Wire cut"
Case (tsk.Name Like "*Laser Welding*"): resName = "Laser Welding"
Case (tsk.Name Like "*Wire cut*"): resName = "Wire cut"
Case (tsk.Name Like "*CNC Milling*"): resName = "CNC Milling"
Case (tsk.Name Like "*Grinding*"): resName = "Grinding"
Case (tsk.Name Like "*Lathe*"): resName = "Lathe"
Case (tsk.Name Like "*Manual Milling*"): resName = "Manual Milling"
Case (tsk.Name Like "*Polishing*"): resName = "Polishing"
Case (tsk.Name Like "*Inspection*"): resName = "CMM"
Case (tsk.Name Like "*Report*"): resName = "CMM"
Case Else: resName = vbNullString
End Select
If Len(resName) > 0 Then
' create the resource assignment
On Error Resume Next
Dim res As Resource
Set res = ActiveProject.Resources(resName)
If Err.Number <> 0 Then
' presume error due to missing resource
Set res = ActiveProject.Resources.Add(Name:=resName)
End If
tsk.Assignments.Add ResourceID:=res.ID
End If
Next tsk
End Sub页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/58677407
复制相关文章
相似问题
腾讯云开发者
