不能终止线程
不能终止线程
提问于 2013-08-14 15:45:26
我在项目中使用线程。我想立刻杀死并终止一条线。
样本：
type
test = class(TThread)
private
{ Private declarations }
protected
procedure Execute; override;
end;
var
Form1: TForm1;
a:tthread;
implementation
{$R *.dfm}
procedure test.Execute;
begin
Synchronize(procedure begin
form1.ProgressBar1.position := 0;
sleep(5000);
form1.ProgressBar1.position := 100;
end
);
end;
procedure TForm1.btn_startClick(Sender: TObject);
begin
a:=test.Create(false);
end;
procedure TForm1.btn_stopClick(Sender: TObject);
begin
terminatethread(a.ThreadID,1); //Force Terminate
end;但是，当我单击btn_stop (单击btn_start之后)时，线程不会停止。，那么如何能够立即停止这个线程呢？
顺便说一句，a.terminate;也不起作用。
谢谢。
回答 2
Stack Overflow用户
回答已采纳
发布于 2013-08-14 16:05:01
这完全是对工作线程的误用。您将所有线程的工作委托给主线程，从而使工作线程毫无用处。你可以用一个简单的计时器代替。
正确使用工作线程看起来更像这样：
type
test = class(TThread)
private
{ Private declarations }
protected
procedure Execute; override;
end;
var
Form1: TForm1;
a: test = nil;
implementation
{$R *.dfm}
procedure test.Execute;
var
I: integer
begin
Synchronize(
procedure begin
form1.ProgressBar1.Position := 0;
end
);
for I := 1 to 5 do
begin
if Terminated then Exit;
Sleep(1000);
if Terminated then Exit;
Synchronize(
procedure begin
Form1.ProgressBar1.Position := I * 20;
end
);
end;
Synchronize(
procedure begin
form1.ProgressBar1.Position := 100;
end
);
end;
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
btn_stopClick(nil);
end;
procedure TForm1.btn_startClick(Sender: TObject);
begin
if a = nil then
a := test.Create(False);
end;
procedure TForm1.btn_stopClick(Sender: TObject);
begin
if a = nil then Exit;
a.Terminate;
a.WaitFor;
FreeAndNil(a);
end;Stack Overflow用户
发布于 2013-08-14 18:40:00
问题是线程通过使用睡眠等待。无论发生什么情况，此方法都将使线程在指定的时间内休眠。为了能够“打破睡眠”，你应该使用一个事件。应将代码更改为：
procedure test.Execute;
begin
Synchronize(procedure begin
form1.ProgressBar1.position := 0;
end);
Event.WaitFor(5000);
if not IsTerminated then
Synchronize(procedure begin
form1.ProgressBar1.position := 100;
end);
end;应该像这样创建和销毁该事件：
constructor test.Create(aCreateSuspended: Boolean);
begin
inherited;
Event := TSimpleEvent.Create;
end;
destructor test.Destroy;
begin
FreeAndNil(Event);
inherited;
end;为了停止线程，代码是：
procedure TForm1.btn_stopClick(Sender: TObject);
begin
a.Terminate;
end;但是，简单地调用Terminate并不意味着事件的发生，因此我们必须重新实现终止：
procedure test.Terminate;
begin
inherited;
Event.SetEvent;
end;调用SetEvent将向事件发出信号，因此它将唤醒线程。在下一行中继续执行，测试线程终止，并决定是否执行代码的第二部分。
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/18236338
复制相关文章
相似问题
腾讯云开发者
