首页
学习
活动
专区
圈层
工具
发布
首页
学习
活动
专区
圈层
工具
MCP广场
社区首页 >问答首页 >检查顺序编号的属性

检查顺序编号的属性
EN

Stack Overflow用户
提问于 2013-10-18 22:08:42
回答 1查看 82关注 0票数 4

在这种情况下,我需要检查属性值,这些属性值可能会被依次编号,并在开始值和结束值之间输入一个破折号。

代码语言:javascript
运行
复制
<root>
<ref id="value00008 value00009 value00010 value00011 value00020"/>
</root>

理想的输出是..。

代码语言:javascript
运行
复制
8-11, 20

我可以将属性标记为单独的值,但我不确定如何检查"valueXXXXX“末尾的数字是否连续于前一个值。

我正在使用XSLT2.0

EN

回答 1

Stack Overflow用户

回答已采纳

发布于 2013-10-19 01:40:17

您可以在xsl:for-each-group@group-adjacent测试中使用number()值减去position()

这个把戏显然是由戴维·卡莱尔据迈克尔·凯说。发明的。

代码语言:javascript
运行
复制
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     version="2.0">
  <xsl:output indent="yes"/>
  <xsl:template match="/">
        <xsl:variable name="vals" 
               select="tokenize(root/ref/@id, '\s?value0*')[normalize-space()]"/>

        <xsl:variable name="condensed-values" as="item()*">

          <xsl:for-each-group select="$vals" 
                              group-adjacent="number(.) - position()">
              <xsl:choose>
                  <xsl:when test="count(current-group()) > 1">
                    <!--a sequence of successive numbers, 
                        grab the first and last one and join with '-' -->
                    <xsl:sequence select="
                               string-join(current-group()[position()=1 
                                              or position()=last()]
                                           ,'-')"/>
                  </xsl:when>
                  <xsl:otherwise>
                      <!--single value group-->
                      <xsl:sequence select="current-group()"/>
                  </xsl:otherwise>
              </xsl:choose>
          </xsl:for-each-group>
        </xsl:variable>

      <xsl:value-of select="string-join($condensed-values, ',')"/>

  </xsl:template>
</xsl:stylesheet>
票数 4
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/19459806

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档