如何从包含特定变量MAPLE的符号表达式中获得部分表达式？
如何从包含特定变量MAPLE的符号表达式中获得部分表达式？
提问于 2018-09-17 13:16:17
我有一个符号表达式如下
y1 = (1/a)-(b/a^2)+x*a*b-x/b
y2 = a*b+a*x+b*sqrt(x)现在我需要得到有特定术语的部分表达式。喜欢
xFunction(y1, x) # should return x*a*b-x/b
xFunction(y2,x) # should return a*x+b*sqrt(x)任何建议或想法都是非常健康的谢谢
回答 2
Stack Overflow用户
回答已采纳
发布于 2018-09-17 14:07:20
restart;
y1 := (1/a)-(b/a^2)+x*a*b-x/b:
y2 := a*b+a*x+b*sqrt(x):
K := (ee,x) -> `if`(ee::`+`,select(depends,ee,x),ee):
K( y1, x );
x
x a b - -
b
K( y2, x );
(1/2)
a x + b x
#
# Leave alone an expression which is not a sum of terms.
#
K( sin(x+4)*x^3, x );
3
sin(x + 4) x
#
# Don't select subterms in which `x` is a just dummy name.
#
K( x^3 + sin(x) + Int(sqrt(x), x=a..b), x );
3
x + sin(x)编辑过的
y1 := (1/a)-(b/a^2)+x*a*b-x/b;
1 b x
y1 := - - -- + x a b - -
a 2 b
a
op(3,y1);
x a b
depends(op(3,y1), x);
trueselect命令将第一个参数映射到第二个参数的所有操作数上。
select( s->depends(s,x), y1 );
x
x a b - -
b一种更简洁的语法，其中select将其第一个参数depends映射到其第二个参数的操作数之上，并将其第三个参数作为附加选项(传递给选择器)。
select( depends, y1, x );
x
x a b - -
b现在创建一个过程来完成它。使用条件测试，以便当第一个参数本身不是项和时，它就返回第一个参数本身。
K1 := proc(ee, x)
if type(ee,`+`) then
select( depends, ee, x );
else
# leave it alone
ee;
end if;
end proc:
K1( y1, x);
x
x a b - -
b对类型检查使用更简洁的语法。
K2 := proc(ee, x)
if ee::`+` then
select( depends, ee, x );
else
# leave it alone
ee;
end if;
end proc:
K2( y1, x);
x
x a b - -
b对该if..then..end if使用更简洁的语法。这就是所谓的if运算符形式.单词if在名字引号中，以区别于if...then...end if中的language关键字。
K3 := proc(ee, x)
`if`( ee::`+` , select( depends, ee, x ), x );
end proc:
K3( y1, x);
x
x a b - -
b因为过程K3的主体只有一条语句，所以我们可以使用所谓的运算符形式使它更加简洁。
K4 := (ee, x) -> `if`( ee::`+` , select( depends, ee, x ), x ):
K4( y1, x);
x
x a b - -
bStack Overflow用户
发布于 2018-09-17 13:45:35
listOfTerms = op(expression); # y1 or y2
numberOfSubExpressions=nops(expression); # for y1 or y2
requiredTerm = 0;
for i 1 to numberOfSubExpressions do
if has(listOfTerms [i], x) then # x is our required term
requiredTerm := requiredTerm +listOfTerms [i]
end if
end do以上代码符合我的要求。但是，如果有什么特殊表达的But，请告诉我。因为op函数的行为不同，当我们有像(sin，因为日志..etc)这样的函数时
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/52368691
复制相关文章
相似问题
腾讯云开发者
