如何在数据行中使用宏变量？
如何在数据行中使用宏变量？
提问于 2017-03-09 09:54:23
%let stmDate = 05FEB2017;
%let stmDueDate = %sysfunc(intnx(day,"&stmDate"d,20),date9.);
data header;
input statement_date date7.
statement_due_date date7.;
format statement_date date7.
statement_due_date date7.;
datalines;
&stmDate &stmDueDate
run;如何解析数据线中的宏变量？
回答 1
Stack Overflow用户
回答已采纳
发布于 2017-03-09 13:10:33
SAS不会扩展DATALINES中的宏代码。请注意，在您的示例程序中不需要。只需使用宏变量来生成设置数据集变量所需的代码。
data header;
statement_date = "&stmDate"d;
statement_due_date = "&stmDueDate"d ;
format statement_date statement_due_date date9.;
run;但是，如果您确实想这样做，那么看一下PROC STREAM，它将解析的行转换为文件，然后从该文件中读取。
所以创建你的宏变量。
%let stmDate = 05FEB2017;
%let stmDueDate = %sysfunc(intnx(day,"&stmDate"d,20),date9.);然后使用PROC STREAM将它们转换为数据文件。你甚至可以调用宏函数。
filename text temp;
proc stream outfile=text; begin
&stmDate &stmDueDate
&stmDate %sysfunc(intnx(day,"&stmDate"d,20),date9.)
;;;;然后从生成的文件中读取。通常，它会删除换行符，因此您可能希望在INPUT语句中使用@@。
data header;
infile text ;
input statement_date statement_due_date @@ ;
format _numeric_ date9.;
informat _numeric_ date9.;
run;页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/42685255
复制相关文章
相似问题
腾讯云开发者
