如何在Autohotkey中将此INI文件转换为listview
如何在Autohotkey中将此INI文件转换为listview
提问于 2017-07-19 20:11:02
我想将这个INI文件排列到一个列表视图中，其中节是第一列，每个键创建另一列。我以为我用这段代码就可以了，但是第二列显示了所有键在一起，而不是分开的。有没有人能帮我把它们分成几列。另外，我在AHK也不是很先进，所以如果你能评论你的步骤将非常感谢！
#SingleInstance, force
#NoEnv
FileDelete,test.ini
FileAppend,
(
[PROJECT-1]
Company=Company A
Remarks=Info about Project 1
Status=Current
Value=Some Value not needed
[PROJECT-2]
Company=Company B
Remarks=Info about Project 2
Status=Late
Values=Some Value not needed
)
,test.ini
GUI, ADD, Listview, w600, PROJECT|COMPANY|REMARKS|STATUS
IniRead, OutputVarProjects, test.ini
; MsgBox % OutputVarProjects
Loop, parse, OutputVarProjects, `n ;shows sections
{
LVDATA:=""
IniRead, OutputVarSection, test.ini, %A_LoopField%
; MsgBox % OutputVarSection
Loop, parse, OutputVarSection, `n
LVDATA .= StrSplit(A_LoopField,"=").2 ","
; MsgBox % LVDATA
LV_Add("", A_loopfield, lvdata)
}
Gui, show
ReturnStack Overflow用户
回答已采纳
发布于 2017-07-19 22:30:41
既然您知道关键字的名称是什么，我的建议是静态地逐个读取它们。动态读取节的键并不能保证它们在一行中会按该顺序出现。
#SingleInstance, force
#NoEnv
FileDelete,test.ini
FileAppend,
(
[PROJECT-1]
Company=Company A
Remarks=Info about Project 1
Status=Current
Value=Some Value not needed
[PROJECT-2]
Company=Company B
Remarks=Info about Project 2
Status=Late
Values=Some Value not needed
)
,test.ini
Gui, Add, Listview, w600, PROJECT|COMPANY|REMARKS|STATUS
IniRead, projects, test.ini
Loop, parse, projects, `n ;shows sections
{
sect := A_LoopField
IniRead, keys, test.ini, % sect
IniRead, company, test.ini, % sect, Company, %A_Space%
IniRead, remarks, test.ini, % sect, Remarks, %A_Space%
IniRead, status, test.ini, % sect, Status, %A_Space%
LV_Add("", sect, company, remarks, status)
}
Loop, % LV_GetCount("Col")
LV_ModifyCol(A_Index, "autoHdr")
Gui, show
return
GuiClose:
ExitApp页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/45190170
复制相关文章
相似问题
腾讯云开发者
