手把手教你 javap 反编译分解代码，授人以鱼不如授人以渔

J2SE 8 = 52 (0x34 hex)
J2SE 7 = 51 (0x33 hex)
J2SE 6.0 = 50 (0x32 hex)
J2SE 5.0 = 49 (0x31 hex)
JDK 1.4 = 48 (0x30 hex)
JDK 1.3 = 47 (0x2F hex)
JDK 1.2 = 46 (0x2E hex)
JDK 1.1 = 45 (0x2D hex)

类型    名称      数量
u1     tag        1
u2     name_index   1
u2     name_index        1

Classfile /Users/zengzhiqin/Desktop/daima/leetcode/out/production/leetcode/TestJVM.class
  Last modified 2020-9-20; size 731 bytes
  MD5 checksum 73a774d54f51805cb2319a2133c47c04
  Compiled from "TestJVM.java"
public class TestJVM
  minor version: 0
  major version: 52
  flags: ACC_PUBLIC, ACC_SUPER
Constant pool:
   #1 = Methodref          #9.#29         // java/lang/Object."<init>":()V
   #2 = Fieldref           #5.#30         // TestJVM.a:I
   #3 = Fieldref           #5.#31         // TestJVM.b:I
   #4 = Fieldref           #32.#33        // java/lang/System.out:Ljava/io/PrintStream;
   #5 = Class              #34            // TestJVM
   #6 = Methodref          #5.#29         // TestJVM."<init>":()V
   #7 = Methodref          #5.#35         // TestJVM.multi:()I
   #8 = Methodref          #36.#37        // java/io/PrintStream.println:(I)V
   #9 = Class              #38            // java/lang/Object
  #10 = Utf8               a
  #11 = Utf8               I
  #12 = Utf8               b
  #13 = Utf8               <init>
  #14 = Utf8               ()V
  #15 = Utf8               Code
  #16 = Utf8               LineNumberTable
  #17 = Utf8               LocalVariableTable
  #18 = Utf8               this
  #19 = Utf8               LTestJVM;
  #20 = Utf8               add
  #21 = Utf8               ()I
  #22 = Utf8               multi
  #23 = Utf8               main
  #24 = Utf8               ([Ljava/lang/String;)V
  #25 = Utf8               args
  #26 = Utf8               [Ljava/lang/String;
  #27 = Utf8               SourceFile
  #28 = Utf8               TestJVM.java
  #29 = NameAndType        #13:#14        // "<init>":()V
  #30 = NameAndType        #10:#11        // a:I
  #31 = NameAndType        #12:#11        // b:I
  #32 = Class              #39            // java/lang/System
  #33 = NameAndType        #40:#41        // out:Ljava/io/PrintStream;
  #34 = Utf8               TestJVM
  #35 = NameAndType        #22:#21        // multi:()I
  #36 = Class              #42            // java/io/PrintStream
  #37 = NameAndType        #43:#44        // println:(I)V
  #38 = Utf8               java/lang/Object
  #39 = Utf8               java/lang/System
  #40 = Utf8               out
  #41 = Utf8               Ljava/io/PrintStream;
  #42 = Utf8               java/io/PrintStream
  #43 = Utf8               println
  #44 = Utf8               (I)V

u2                 0x0002 -> 第一个跟着的是fields_count,这个类只有2个字段表数据

以下是字段表内容：
u2                 0x0002   private为真，其他为假
u2                 0x000a   字段名称name_index,由上面JAVAP常量表可知#10为a
u2                 0x000b   字段描述符descriptor_index,由上面JAVAP常量表可知#11指        向常量池字符串I，这个描述符标识字符含义 标识基本类型int
u2                 0x0000   attribute_count 属性表集合无属性，为0表示没有额外描述的信息
attribute_info    上面无内容，不占字节   

u2                 0x0004 -> 第一个跟着的是方法数量,这个类有4个方法表数据，分别是         add(),multi(),main()和构造器方法

以下是第一个方法表内容：
u2                 0x0001   public为真，其他为假
u2                 0x000d   方法简单名称name_index,由上面JAVAP常量表可知#14为()v,v由描述          符含义可知是特殊类型void,()代表无参数，即构造函数
u2                 0x000e   方法描述符descriptor_index,由上面JAVAP常量表可知#15指         Code,Code之后再讲        
u2           0x0001   attribute_count,属性表集合有一项属性用于存储一些额外信息
attribute_info     0x000f   由JAVAP看到的指令，指向#15,即对应常量”Code“，说明此属性是方法的
       字节码描述

常量表前面已经贴出了
{
 public int b;
   descriptor: I
   flags: ACC_PUBLIC

 public TestJVM();
   descriptor: ()V
   flags: ACC_PUBLIC
   Code:
     stack=2, locals=1, args_size=1
        0: aload_0
        1: invokespecial #1                  // Method java/lang/Object."<init>":()V
        4: aload_0
        5: iconst_3
        6: putfield      #2                  // Field a:I
        9: aload_0
       10: iconst_4
       11: putfield      #3                  // Field b:I
       14: return
     LineNumberTable:
       line 5: 0
       line 6: 4
       line 7: 9
     LocalVariableTable:
       Start  Length  Slot  Name   Signature
           0      15     0  this   LTestJVM;

 public int add();
   descriptor: ()I
   flags: ACC_PUBLIC
   Code:
     stack=2, locals=1, args_size=1
        0: aload_0
        1: getfield      #2                  // Field a:I
        4: aload_0
        5: getfield      #3                  // Field b:I
        8: iadd
        9: ireturn
     LineNumberTable:
       line 10: 0
     LocalVariableTable:
       Start  Length  Slot  Name   Signature
           0      10     0  this   LTestJVM;

 public int multi();
   descriptor: ()I
   flags: ACC_PUBLIC
   Code:
     stack=2, locals=1, args_size=1
        0: aload_0
        1: getfield      #2                  // Field a:I
        4: aload_0
        5: getfield      #3                  // Field b:I
        8: imul
        9: ireturn
     LineNumberTable:
       line 14: 0
     LocalVariableTable:
       Start  Length  Slot  Name   Signature
           0      10     0  this   LTestJVM;

 public static void main(java.lang.String[]);
   descriptor: ([Ljava/lang/String;)V
   flags: ACC_PUBLIC, ACC_STATIC
   Code:
     stack=3, locals=1, args_size=1
        0: getstatic     #4                  // Field java/lang/System.out:Ljava/io/PrintStream;
        3: new           #5                  // class TestJVM
        6: dup
        7: invokespecial #6                  // Method "<init>":()V
       10: invokevirtual #7                  // Method multi:()I
       13: invokevirtual #8                  // Method java/io/PrintStream.println:(I)V
       16: return
     LineNumberTable:
       line 18: 0
       line 20: 16
     LocalVariableTable:
       Start  Length  Slot  Name   Signature
           0      17     0  args   [Ljava/lang/String;
}
SourceFile: "TestJVM.java"

/**
 * @author by zengzhiqin
 * 2020-09-13
 */
public class TestException {
    public int inc() {
        int x;
        try {
            x = 1;
            return x;
        } catch (Exception e) {
            x = 2;
            return x;
        } finally {
            x= 3;
        }
    }
    

}

0: iconst_0        //常量0压入操作数栈
1: istore_2        //弹出操作数栈栈顶元素，保存到局部变量表第2个位置
2: iload_0         //第0个变量压入操作数栈顶
3: iload_1         //第1个变量压入操作数栈顶
4: iadd            //操作数栈中的前两个int相加，并将结果压入操作数栈顶
5: istore_2        //弹出操作数栈栈顶元素，保存到局部变量表第2个位置
6: iload_2         //加载局部变量表的第2个变量到操作数栈顶
7: ireturn         //返回
8：aload           //从局部变量表的相应位置装载一个对象引用到操作数栈的栈顶

zengzhiqin@cengzhiqindeMacBook-Pro  ~/Desktop/daima/leetcode/src  javap -c TestException
Compiled from "TestException.java"
public class TestException {
  public TestException();
    Code:
       0: aload_0
       1: invokespecial #1                  // Method java/lang/Object."<init>":()V
       4: return

  public int inc();
    Code:
       0: iconst_1     // try中x=1,1压入操作数栈
       1: istore_1     //将1从操作数栈存储到局部变量表第一个位置,x=1
       2: iload_1     // 加载局部变量表第一个位置元素到操作数栈顶
       3: istore_2    // 弹出操作数栈顶元素1，保存到局部变量表第2个位置
       4: iconst_3     // finally块中x=3，将3压入操作数栈
       5: istore_1     // 弹出栈顶元素3，将其保存到局部变量表第1个位置
       6: iload_2     // 将变量表第2个位置值1放到栈顶，准备给ireturn返回
       7: ireturn      // 正常情况下返回 1 正确吻合~
       
       8: astore_2    // 给catch中定义的 Exception e 赋值，存储在slot 2中
       9: iconst_2    // catch 中 x=2，2压入操作数栈
      10: istore_1    // 弹出栈顶的2，保存到slot 1
      11: iload_1    // 局部变量表第1个位置的2压入栈顶
      12: istore_3   // 弹出栈顶元素2保存到局部变量第3个位置
      13: iconst_3    // finally中x=3，将3压入操作数栈
      14: istore_1    // 将3放到局部变量表第1个位置，准备给ireturn返回
      15: iload_3     // 加载局部变量表第3个位置的值2到栈顶
      16: ireturn     // 返回栈顶元素2  catch异常返回2 正确，吻合
      
      17: astore        4     // 如果出现了不属于java.lang.Exception及其子类异常走到这里
      19: iconst_3    // finally块中x=3，将3压入操作数栈
      20: istore_1     // 将3存储到局部变量表第1个位置      
      21: aload         4     // 将异常引用放在栈顶，并且抛出
      23: athrow              // 抛出异常
    Exception table:
       from    to  target type
           0     4     8   Class java/lang/Exception
           0     4    17   any
           8    13    17   any
          17    19    17   any
}