我有一个返回输出的命令:
$ show
file 1 banana
file 3 apple
file 2 watermelon
file 0 tomato
file name 0=abc 1=def
2=ghi 3=jkl
使用给定的文件名,我希望找到相关的单词。例如,ghi
将与watermelon
匹配。
我可以用sed
匹配文件编号并重用结果:
$ filenum=$(show | sed -n 's/.*\<\([0-9]*\)=ghi\>.*/\1/p')
$ show | sed -n 's/file '"$filenum"' \([a-z]*\)/\1/p'
watermelon
show
的输出计算起来可能会很长,所以我想避免两次调用它。还可以将输出存储在变量中并执行相同的操作:
$ out=$(show)
$ filenum=$(echo "$out" | sed -n 's/.*\<\([0-9]*\)=ghi\>.*/\1/p')
$ echo "$out" | sed -n 's/file '"$filenum"' \([a-z]*\)/\1/p'
watermelon
但是我想用最少的命令来做这件事。
只需调用一次sed
、awk
或任何类似的实用程序就可以达到相同的结果吗?
我想要一个命令magic-command
,对于给定的文件名,在show
命令的输出中打印相关的单词。例如:
$ show | magic-command "ghi"
watermelon
$ show | magic-command "abc"
tomato
$ show | magic-command "def"
banana
show
命令的格式如下:
file <filenum> <word>
...
file name <filenum>=<filename> ...
EDIT 2谢谢你的回答,我以前从来没有用过awk
,所以我学到了很多,谢谢你!因此,我对它们进行了修补,并最终得到了以下结果:
$ cat magic-command.sh
#!/bin/sh
awk '
# Match the `<filenum>=<filename>` using the given <filename>
# to find to <filenum>
match($0, /([0-9]*)='"$1"'/, out ) {
filenum=out[1]
}
# Fill n2name using the `file <filenume> <word>` lines
/\<file [0-9]*\>/ {
n2name[$2]=$3
}
END {
print n2name[filenum]
}'
然后:
$ show | ./magic-command.sh "ghi"
watermelon
发布于 2018-07-12 22:32:23
$ cat tst.awk
/=/ {
for (i=1; i<=NF; i++) {
if ( split($i,f,/=/) == 2 ) {
name2nr[f[2]] = f[1]
}
}
next
}
{ nr2text[$2] = $3 }
END { print nr2text[name2nr[name]] }
使用cat file
(其中file
包含问题中提供的show
的输出)代替show
$ cat file | awk -v name='ghi' -f tst.awk
watermelon
如果文件名可以包含=
或空格,则上述方法(以及其他当前发布的答案和任何其他明显的解决方案)都将失败。如果可能发生这种情况,那么您需要告诉我们如何识别文件名,而不是字段和/或赋值语句。
发布于 2018-07-12 11:59:02
编辑:根据操作添加解决方案,操作需要与另一个程序一起运行,然后尝试以下操作。
cat script.ksh
your_command | awk -v command="$1" -F' +|=' '
/^file/ && !/^file name/{
a[$2]=$NF
}
/^file name/{
for(i=3;i<=NF;i+=2){
array[$i]=$(i+1)}
}
/^ +/{
for(j=2;j<=NF;j+=2){
array[$j]=$(j+1)}
}
END{
for(i in array){
if(array[i]==command){ print array[i],a[i] }
}}'
以下是我们运行脚本时的输出。
./script.ksh "ghi"
ghi watermelon
在你的帖子中仍然有很多问题是不清楚的,完全基于你发布的内容,试着关注一次(根据你的样本完全显示)。
awk -F' +|=' '
FNR==NR{
if($0 ~ /file name/){
for(i=3;i<=NF;i+=2){
array[$i]=$(i+1)
}
getline
for(j=2;j<=NF;j+=2){
array[$j]=$(j+1)
}
}
next
}
($2 in array){
print array[$2],$NF
}' Input_file Input_file
输出如下所示。
def banana
jkl apple
ghi watermelon
abc tomato
ghi jkl
考虑到您的show
函数在这里输出到一个Input_file
中,而我在这里读取Input_file 2次。
https://stackoverflow.com/questions/51296561
复制相似问题