如何在VBA (Excel)中获取以毫秒为单位的DateDiff值？
如何在VBA (Excel)中获取以毫秒为单位的DateDiff值？
提问于 2009-06-02 12:24:44
我需要以毫秒为单位计算两个时间戳之间的差值。不幸的是，VBA的DateDiff函数没有提供这种精度。有什么变通方法吗？
回答 6
Stack Overflow用户
回答已采纳
发布于 2009-06-02 12:35:21
您可以使用here描述的方法，如下所示：
创建一个名为StopWatch的新类模块，将以下代码放入StopWatch类模块：
Private mlngStart As Long
Private Declare Function GetTickCount Lib "kernel32" () As Long
Public Sub StartTimer()
mlngStart = GetTickCount
End Sub
Public Function EndTimer() As Long
EndTimer = (GetTickCount - mlngStart)
End Function您可以按如下方式使用代码：
Dim sw as StopWatch
Set sw = New StopWatch
sw.StartTimer
' Do whatever you want to time here
Debug.Print "That took: " & sw.EndTimer & "milliseconds"其他方法描述了VBA计时器功能的使用，但这只能精确到百分之一秒(厘米秒)。
Stack Overflow用户
发布于 2009-06-02 18:58:19
如果您只需要以厘米为单位的时间，那么您不需要TickCount应用编程接口。您可以只使用所有Office产品中都存在的VBA.Timer方法。
Public Sub TestHarness()
Dim fTimeStart As Single
Dim fTimeEnd As Single
fTimeStart = Timer
SomeProcedure
fTimeEnd = Timer
Debug.Print Format$((fTimeEnd - fTimeStart) * 100!, "0.00 "" Centiseconds Elapsed""")
End Sub
Public Sub SomeProcedure()
Dim i As Long, r As Double
For i = 0& To 10000000
r = Rnd
Next
End SubStack Overflow用户
发布于 2009-06-04 01:56:16
如果要进行微秒级操作，则需要GetTickCount和性能计数器。对于毫秒，你可以使用像这样的东西。
'at the bigining of the module
Private Type SYSTEMTIME
wYear As Integer
wMonth As Integer
wDayOfWeek As Integer
wDay As Integer
wHour As Integer
wMinute As Integer
wSecond As Integer
wMilliseconds As Integer
End Type
Private Declare Sub GetLocalTime Lib "kernel32" (lpSystemTime As SYSTEMTIME)
'In the Function where you need find diff
Dim sSysTime As SYSTEMTIME
Dim iStartSec As Long, iCurrentSec As Long
GetLocalTime sSysTime
iStartSec = CLng(sSysTime.wSecond) * 1000 + sSysTime.wMilliseconds
'do your stuff spending few milliseconds
GetLocalTime sSysTime ' get the new time
iCurrentSec=CLng(sSysTime.wSecond) * 1000 + sSysTime.wMilliseconds
'Different between iStartSec and iCurrentSec will give you diff in MilliSecs页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/939230
复制相关文章
相似问题