问迭代并将XSLT标识转换应用到文档目录中？
EN

Stack Overflow用户

提问于 2016-01-15 04:15:33

回答 3查看 426关注 0票数 1

我有一个包含HTML文件的文件夹，其外观大致如下所示：

<div id="d10e3019" class="content">
   <h1>header</h1>
   <div class="adv">
      <div class="warn">
         <img width="60px" height="20px" src="img/warn.png" alt="WARNING"></img>
         <p class="cause">gfgfg!</p>
         <p>⇒  Thgfh</p>
         <p class="step">⇔ 
            <span class="emphasis">hgfh
         </p>
      </div>
   </div>
</div>

它们都有<div id="someId" class="content">作为根元素，然后只是各种HTML。

我需要更改每个文档的src标记中的所有img属性，如下所示：

<img width="60px" height="20px" src="http://server.com/{$nameOfTheCurtentFolder}/img/warn.png" alt="WARNING"></img>

并使用新的子元素将新输出包装在另一个div中。文档的其余部分需要完全相同。

我尝试了这个样式表，但是使用这个样式表，只有文本节点被写入输出文档中(同时生成新的div元素工作)：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version='2.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform' xmlns:xs='http://www.w3.org/2001/XMLSchema' xmlns:fn='http://www.w3.org/2005/xpath-functions' exclude-result-prefixes='xsl xs fn' xmlns:h="http://java.sun.com/jsf/html">
    <xsl:output method="xml" encoding="utf-8"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="files" select="collection('./output?select=*.html')"/>

    <xsl:template match="/">
        <xsl:for-each select="$files">
            <xsl:variable name="fileName" select="tokenize(base-uri(), '/')[last()]"/>
            <xsl:result-document method="xhtml" href="new/{$fileName}">
                <div>
                    <h:selectBooleanCheckbox value="pubs"/>
                    <xsl:copy>
                        <xsl:apply-templates select="@* | node()"/>
                    </xsl:copy>
                </div>
            </xsl:result-document>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="@src">
        <xsl:variable name="nameOfTheCurtentFolder" select="tokenize(base-uri(), '/')[last()-2]"/>
        <xsl:text>http://server.com/</xsl:text>
        <xsl:value-of select="$nameOfTheCurtentFolder"/>
        <xsl:text>/output/</xsl:text>
        <xsl:value-of select="."/>
    </xsl:template>
</xsl:stylesheet>

输出如下所示：

              <div>
                 <h:selectBooleanCheckbox value="pubs"/>
                  headergfgfg!⇒  Thgfhhgfh
              </div>

这是我先前问题的后续，Change attribute value without creating new output document?。

xml

xslt

xslt-2.0

人脸识别特惠活动

精准实时的人脸检测、分析、识别等服务，在线、离线满足多样需求，可应用于智慧零售、智慧社区、在线娱乐等多种应用场景

回答 3

Stack Overflow用户

回答已采纳

发布于 2016-01-15 04:55:08

您的样式表似乎缺少了标识转换模板：

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

此外，为了更改属性值，您需要首先重新创建它：

<xsl:template match="@src">
    <xsl:attribute name="src">
        <xsl:variable name="nameOfTheCurtentFolder" select="tokenize(base-uri(), '/')[last()-2]"/>
        <xsl:text>http://server.com/</xsl:text>
        <xsl:value-of select="$nameOfTheCurtentFolder"/>
        <xsl:text>/output/</xsl:text>
        <xsl:value-of select="."/>
    </xsl:attribute>
</xsl:template>

最后，要处理的HTML文档也必须是格式良好的XML；提供的示例不是。

票数 2

Stack Overflow用户

发布于 2016-01-15 05:02:05

它也开始工作了，只晚了5分钟(与michael.hor257k相比)：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version='2.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform' xmlns:xs='http://www.w3.org/2001/XMLSchema' xmlns:fn='http://www.w3.org/2005/xpath-functions' exclude-result-prefixes='xsl xs fn' xmlns:h="http://java.sun.com/jsf/html">
    <xsl:output method="xml" encoding="utf-8"/>
    <xsl:strip-space elements="*"/>
    <xsl:param name="files" select="collection('./output/*.xml')"/>
    <xsl:template match="/">
        <xsl:for-each select="$files">
            <xsl:variable name="fileName" select="tokenize(base-uri(), '/')[last()]"/>
            <xsl:result-document method="xhtml" href="new/{$fileName}">
                <div>
                    <h:selectBooleanCheckbox value="pubs"/>
                    <xsl:copy>
                        <xsl:apply-templates/>
                    </xsl:copy>
                </div>
            </xsl:result-document>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="@src">
        <xsl:attribute name="src">
            <xsl:variable name="nameOfTheCurtentFolder" select="tokenize(base-uri(), '/')[last()-2]"/>
            <xsl:text>http://server.com/</xsl:text>
            <xsl:value-of select="$nameOfTheCurtentFolder"/>
            <xsl:text>/output/</xsl:text>
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>
</xsl:stylesheet>

票数 1

Stack Overflow用户

发布于 2016-01-15 05:39:05

通解

XSLT没有在文件目录中迭代的标准方法。您应该通过外部控制应用XSLT来实现这种效果。collection()函数的Saxon扩展，但是，它可以这样做.

迭代输入文档并应用标识变换

The following XSLT will apply an adjusted identity transformation to all `$inSubdirName` HTML files and place the results in `$outSubdirName`:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version='2.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>
    <xsl:output omit-xml-declaration="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:param name="inSubdirName" select="'in'"/>
  <xsl:param name="outSubdirName" select="'out'"/>

  <!-- Driver for each file in inSubdirName -->
  <xsl:template match="/">
    <xsl:for-each select="collection(concat($inSubdirName, '/?select=*.html'))">
      <xsl:variable name="inFileName" select="base-uri()"/>
      <xsl:variable name="outFileName"
                    select="concat($outSubdirName, '/',
                            tokenize(base-uri(), '/')[last()])"/>
      <xsl:message select="concat('Transforming from ',
                           $inFileName, ' to ', $outFileName)"/>
      <xsl:result-document method="xhtml" href="{$outFileName}">
        <xsl:apply-templates select="@*|node()"/>
      </xsl:result-document>
    </xsl:for-each>
  </xsl:template>

  <!-- Identity transform -->
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <!-- Identity transform overrides -->
  <xsl:template match="/div">
    <div xmlns:h="http://java.sun.com/jsf/html">
      <h:selectBooleanCheckbox value="pubs"/>
      <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
    </div>
  </xsl:template>

  <xsl:template match="@src">
    <xsl:attribute name="src">
      <xsl:variable name="nameOfTheCurrentFolder"
                    select="tokenize(base-uri(), '/')[last()-2]"/>
      <xsl:text>http://server.com/</xsl:text>
      <xsl:value-of select="$nameOfTheCurrentFolder"/>
      <xsl:text>/output/</xsl:text>
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>

</xsl:stylesheet>

应用于输入HTML文件时，如您所提供的，更正为格式良好：。

<div id="d10e3019" class="content">
   <h1>header 1</h1>
   <div class="adv">
      <div class="warn">
         <img width="60px" height="20px" src="img/warn.png" alt="WARNING"></img>
         <p class="cause">gfgfg!</p>
         <p>⇒  Thgfh</p>
         <p class="step">⇔ 
            <span class="emphasis">hgfh</span>
         </p>
      </div>
   </div>
</div>

@src将使用新的属性以及新的 div 和 h:selectBooleanCheckbox 子元素来转换它们。

<div xmlns:h="http://java.sun.com/jsf/html">
   <h:selectBooleanCheckbox value="pubs"></h:selectBooleanCheckbox>
   <div id="d10e3019" class="content">
      <h1>header 1</h1>
      <div class="adv">
         <div class="warn">
            <img width="60px" height="20px" src="http://server.com/xslt/output/img/warn.png" alt="WARNING"></img>
            <p class="cause">gfgfg!</p>
            <p>⇒  Thgfh</p>
            <p class="step">⇔ 

               <span class="emphasis">hgfh</span>
            </p>
         </div>
      </div>
   </div>
</div>